# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Contributor (Arch): Eschwartz <eschwartz93@gmail.com>

pkgname=iceweasel-noscript

pkgver=5.1.5
pkgrel=1
arch=(any)

pkgdesc="Extension for iceweasel which disables script"
url="https://noscript.net/"
license=(GPL2)

depends=(iceweasel)
makedepends=(unzip)
replaces=(firefox-noscript)
groups=(iceweasel-addons)

source=(https://secure.informaction.com/download/releases/noscript-$pkgver.xpi)
noextract=("noscript-$pkgver.xpi")
sha256sums=('0620b8608441b5a346e347a07ce3c1e707edc8d4d04f2c72af53e73a0d9b6d5c')

prepare() {
  unzip -qqo "noscript-$pkgver.xpi" -d "noscript-$pkgver"
}

package() {
  _extension_id="$(sed -n '/.*<em:id>\(.*\)<\/em:id>.*/{s//\1/p;q}' noscript-$pkgver/install.rdf)"
  _extension_dest="$pkgdir/usr/lib/iceweasel/browser/extensions/$_extension_id"

  if grep '<em:unpack>true</em:unpack>' noscript-$pkgver/install.rdf > /dev/null; then
    install -dm755 "$_extension_dest"
    cp -R noscript-$pkgver/* "$_extension_dest"
    chmod -R ugo+rX "$_extension_dest"
  else
    install -Dm644 noscript-$pkgver.xpi "$_extension_dest.xpi"
  fi
}