# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: jc_gargma <jc_gargma@iserlohn-fortress.net>
# Contributor (Arch): Eschwartz <eschwartz93@gmail.com>

pkgname=icecat-noscript

pkgver=5.1.8.3
pkgrel=1
arch=(any)

pkgdesc="Extension for icecat which disables script"
url="https://noscript.net/"
license=(GPL2)

depends=(icecat)
makedepends=(unzip)
groups=(icecat-addons)

source=(https://secure.informaction.com/download/releases/noscript-$pkgver.xpi)
noextract=("noscript-$pkgver.xpi")
sha256sums=('9a81de6e26f639e5f82cabddcd361177815c59af2bca6363ba755255feffd2ec')

prepare() {
  unzip -qqo "noscript-$pkgver.xpi" -d "noscript-$pkgver"
}

package() {
  _extension_id="$(sed -n '/.*<em:id>\(.*\)<\/em:id>.*/{s//\1/p;q}' noscript-$pkgver/install.rdf)"
  _extension_dest="$pkgdir/usr/lib/icecat/browser/extensions/$_extension_id"

  if grep '<em:unpack>true</em:unpack>' noscript-$pkgver/install.rdf > /dev/null; then
    install -dm755 "$_extension_dest"
    cp -R noscript-$pkgver/* "$_extension_dest"
    chmod -R ugo+rX "$_extension_dest"
  else
    install -Dm644 noscript-$pkgver.xpi "$_extension_dest.xpi"
  fi
}