# $Id$
# Maintainer (Arch): Kyle Keen <keenerd@gmail.com>
# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>

_pkgname=seamonkey
pkgname=iceape
epoch=1
pkgver=2.49.2
pkgrel=1
_bver=2.48
_brel=1
pkgdesc="Iceape, the libre internet suite based on SeaMonkey."
arch=('x86_64')
arch+=('i686' 'armv7h')
license=('MPL')
depends=('alsa-lib'  'dbus-glib'  'desktop-file-utils'  'gtk2' 'gtk3' 'hunspell'  'libevent'  'libnotify'  'libvpx'  'libxt' 'mime-types'  'mozilla-common'  'nss'  'sqlite'  'startup-notification' 'libpulse' 'icu' 'gconf')
depends+=('icu>=61' 'icu<62')
makedepends=('unzip' 'zip' 'pkg-config'  'python2' 'yasm' 'wireless_tools' 'mesa' 'autoconf2.13' 'imake' 'python3' 'gst-plugins-base')
makedepends+=('mozilla-searchplugins' 'quilt')
optdepends=('gst-plugins-base: vorbis decoding, ogg demuxing'
            'gst-plugins-bad: aac, vp8 and opus decoding'
            'gst-plugins-good: webm and mp4 demuxing'
            'gst-plugins-ugly: h.264 decoding')
url="https://wiki.parabola.nu/$pkgname"
replaces=("$_pkgname")
conflicts=("$_pkgname")
source=(https://archive.mozilla.org/pub/mozilla.org/seamonkey/releases/$pkgver/source/seamonkey-$pkgver.source.tar.xz
        mozconfig
        $pkgname-2.0-lang.patch
        rhbz-966424.patch
        mozbug1323209.patch
        mozbug1329272.patch
	no-crmf.diff)
source+=(https://repo.parabola.nu/other/$pkgname/${pkgname}_$_bver-$_brel.branding.tar.xz{,.sig}
         libre.patch $pkgname.desktop)
sha256sums=('09fc9f8b1817a901b4e0d7635701ab50236885821d73694ac21615c8d911b575'
            '1e88c4f6a1bd8170a714087325c3ba0b88c0b4352c4cd4db58317a3a0d2271c4'
            'ab19d10fbd6258aec37ab5e5efb12429814b2c24a1193284a48dd654311b4e2e'
            '746cb474c5a2c26fc474256e430e035e604b71b27df1003d4af85018fa263f4a'
            '87fb92e45f161d47b9e3ca31bcce60555bc33d633116dab4baa3bfba6ad965c4'
            '33c7031781357faf5fba7140d7723bf301c1569068922477742ac958ee82e62b'
            'fb85a538044c15471c12cf561d6aa74570f8de7b054a7063ef88ee1bdfc1ccbb'
            '2fd3568b07e4dddb0f81201c273c7a5ebb2ba837f49f71683b98f374d03134b4'
            'SKIP'
            '8055e44151f007dd176d2bc545aa3ce282e9b1a59b35ca1f9f93d1c3e21689cd'
            '46ac418fe26937460a36a593d71c8f5cef1288c9e747cac4ec4ca92db56da45d')
validpgpkeys=('BFA8008A8265677063B11BF47171986E4B745536') # Andreas Grapentin

prepare() {
  cd "$_pkgname-$pkgver"
  cp ../mozconfig .mozconfig
  #patch -Np1 -i ../$pkgname-2.0-lang.patch

  # perform branding
  install -m755 -d $pkgname
  mv -v "$srcdir"/$pkgname-$_bver/{branding,extras,patches} $pkgname

  export QUILT_PATCHES=$pkgname/patches
  export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
  export QUILT_DIFF_ARGS='--no-timestamps'

  quilt push -av

  # set up a simple non-animated throbber from the icon
  for throbber_target_gif in suite/themes/{classic,modern}/communicator/brand/throbber{,16}-anim.png; do
    install -m644 $pkgname/extras/Throbber-small.gif $throbber_target_gif
  done
  for throbber_target_png in suite/themes/{classic,modern}/communicator/brand/throbber{,16}-single.png; do
    install -m644 $pkgname/extras/Throbber-small.png $throbber_target_png
  done

  install -m644 $pkgname/extras/preview.png suite/themes/classic

  # Convert svg file to png and replace seamonkey to iceape icons
  _bdir=$pkgname/branding
  brandingdir=suite/branding/nightly
  for i in 16 48; do
    rsvg-convert -w $i -h $i $_bdir/${pkgname}_icon_plain.svg \
      -o $brandingdir/icons/gtk/default$i.png
    rsvg-convert -w $i -h $i $_bdir/${pkgname}_icon_plain.svg \
      -o $brandingdir/icons/gtk/main-window$i.png
  done

  for i in 32 48 64; do
    rsvg-convert -w $i -h $i $_bdir/${pkgname}_icon_plain.svg \
      -o $brandingdir/content/icon$i.png
  done

  rsvg-convert -w 32 -h 32 $_bdir/${pkgname}_icon_plain.svg \
    -o $brandingdir/icons/gtk/default.png
  rsvg-convert -w 32 -h 32 $_bdir/${pkgname}_icon_plain.svg \
    -o $brandingdir/icons/gtk/main-window.png
  rsvg-convert -w 128 -h 128 $_bdir/${pkgname}_icon_plain.svg \
    -o $brandingdir/icons/gtk/${pkgname}.png
  rsvg-convert -w 200 -h 200 $_bdir/${pkgname}_icon_plain.svg \
    -o $brandingdir/content/logo.gif
  rsvg-convert -w 300 -h 280 $_bdir/${pkgname}_logo_plain.svg \
    -o $brandingdir/content/about.png
  rsvg-convert -w 1138 -h 1152 $_bdir/${pkgname}_background_plain.svg \
    -o $brandingdir/content/messenger-start-bg.png

  # Create app-icons folder for iceape*.png icons
  install -m755 -d $_bdir/app-icons

  # Icons for /usr/share/icons/hicolor
  for i in 16 32 48 64 128; do
    rsvg-convert -w $i -h $i $_bdir/${pkgname}_icon_plain.svg \
      -o $_bdir/app-icons/$pkgname${i}.png
  done

  patch -Np1 -i "$srcdir/libre.patch"

  # FS#48404
  #echo "ac_add_options --enable-gstreamer=1.0" >> .mozconfig

  # https://bugs.archlinux.org/task/41689
  #patch -Np1 -d mozilla -i ../../rhbz-966424.patch

  # Support NSS 3.28
  #patch -Np1 -d mozilla -i ../../mozbug1323209.patch

  # Bugfix for icu detection
  #patch -Np1 -d mozilla -i ../../mozbug1329272.patch

  # Don't exit with error when some libs are missing which we have in
  # system.
  sed -i '/^MOZ_PKG_FATAL_WARNINGS/s@= 1@= 0@' suite/installer/Makefile.in

  # configure script misdetects the preprocessor without an optimization level
  sed -i '/ac_cpp=/s/$CPPFLAGS/& -O2/' configure

  # 2.26 build fix from wgnie (blfs ch 37)
  sed -i 's/$(MOZ_ZLIB_CFLAGS)/& $(MOZ_PIXMAN_CFLAGS)/' config/config.mk

  # work around from FS#54395
  patch -Np1 -d mozilla -i ../../no-crmf.diff
  sed -i "s/'crmf',//" mozilla/security/manager/ssl/moz.build
}

build() {
  cd "$_pkgname-$pkgver"

  export LDFLAGS="$LDFLAGS -Wl,-rpath,/usr/lib/$pkgname-$pkgver"
  export MOZ_MAKE_FLAGS="$MAKEFLAGS"
  unset MAKEFLAGS
  unset CPPFLAGS

  # GCC 6
  CFLAGS+=" -fno-delete-null-pointer-checks -fno-lifetime-dse -fno-schedule-insns2"
  CXXFLAGS+=" -fno-delete-null-pointer-checks -fno-lifetime-dse -fno-schedule-insns2"

  make -j1 -f client.mk build
}

package() {
  cd "$_pkgname-$pkgver"

  make -j1 -f client.mk DESTDIR="$pkgdir" INSTALL_SDK= install

  rm -rf "$pkgdir"/usr/lib/$pkgname-$pkgver/{dictionaries,hyphenation,searchplugins}
  ln -s /usr/share/hunspell "$pkgdir/usr/lib/$pkgname-$pkgver/dictionaries"
  ln -s /usr/share/hyphen "$pkgdir/usr/lib/$pkgname-$pkgver/hyphenation"
  ln -s /usr/lib/mozilla/searchplugins "$pkgdir/usr/lib/$pkgname-$pkgver/searchplugins"

  install -Dm644 suite/branding/nightly/icons/gtk/iceape.png \
                "$pkgdir/usr/share/pixmaps/seamonkey.png"

  install -Dm644 "$srcdir/$pkgname.desktop" \
                "$pkgdir/usr/share/applications/$pkgname.desktop"

  for i in 16 32 48 64 128; do
      install -Dm644 $pkgname/branding/app-icons/$pkgname$i.png \
                    "$pkgdir/usr/share/icons/hicolor/${i}x${i}/apps/$pkgname.png"
  done
  install -Dm644 $pkgname/branding/${pkgname}_icon_plain.svg \
                "$pkgdir/usr/share/icons/hicolor/scalable/apps/$pkgname.svg"

  rm -f "$pkgdir/usr/lib/pkgconfig/"$pkgname-ns{s,pr}.pc
  #rm -r "$pkgdir"/usr/{include,lib/$pkgname-devel-$pkgver,share/idl}
}