# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

epoch=1
_pkgbase=iceape
pkgbase=$_pkgbase-l10n
pkgver=2.39
pkgrel=1
pkgdesc="Language pack for Debian ${_pkgbase^}."
arch=('any')
url="https://wiki.parabola.nu/$_pkgbase"
license=('MPL' 'GPL')
depends=("$_pkgbase=$epoch:$pkgver")
makedepends=('unzip' 'zip')

_languages=(
  'be     "Belarusian"'
  'ca     "Catalan"'
  'cs     "Czech"'
  'de     "German"'
  'en-GB  "English (British)"'
  'es-AR  "Spanish (Argentina)"'
  'es-ES  "Spanish (Spain)"'
  'fi     "Finnish"'
  'fr     "French"'
  'gl     "Galician"'
  'hu     "Hungarian"'
  'it     "Italian"'
  'ja     "Japanese"'
  'lt     "Lithuanian"'
  'nb-NO  "Norwegian (Bokmål)"'
  'nl     "Dutch"'
  'pl     "Polish"'
  'pt-PT  "Portuguese (Portugal)"'
  'ru     "Russian"'
  'sk     "Slovak"'
  'sv-SE  "Swedish"'
  'tr     "Turkish"'
  'uk     "Ukrainian"'
  'zh-CN  "Chinese (Simplified)"'
  'zh-TW  "Chinese (Traditional)"'
)

pkgname=()
source=('brand.dtd' 'brand.properties' 'communicator-region.properties' 'editor-region.properties' 'messenger-region.properties' 'navigator-region.properties')
_url=https://ftp.mozilla.org/pub/seamonkey/releases/$pkgver/langpack

for _lang in "${_languages[@]}"; do
  _locale=${_lang%% *}
  _pkgname=$pkgbase-${_locale,,}

  pkgname+=($_pkgname)
  source+=("$pkgbase-$pkgver-$_locale.xpi::$_url/seamonkey-$pkgver.$_locale.langpack.xpi")
  eval "package_$_pkgname() {
    _package $_lang
  }"
done

# Don't extract anything
noextract=(${source[@]%%::*})

_package() {
  pkgdesc="$2 language pack for Debian Iceape."
  replaces=(iceape-i18n-${1,,})
  conflicts=(iceape-i18n-${1,,})
  provides=(iceape-i18n-${1,,})

  unzip iceape-l10n-$pkgver-$1.xpi -d $1
  rm -v iceape-l10n-$pkgver-$1.xpi
  install -vDm644 $srcdir/brand.dtd $1/chrome/$1/locale/$1/branding
  install -vDm644 $srcdir/brand.properties $1/chrome/$1/locale/$1/branding
  install -vDm644 $srcdir/navigator-region.properties $1/chrome/$1/locale/$1/navigator-region/region.properties
  install -vDm644 $srcdir/messenger-region.properties $1/chrome/$1/locale/$1/messenger-region/region.properties
  install -vDm644 $srcdir/communicator-region.properties $1/chrome/$1/locale/$1/communicator-region/region.properties
  install -vDm644 $srcdir/editor-region.properties $1/chrome/$1/locale/$1/editor-region/region.properties
  sed -i -e 's/seamonkey/iceape/' $1/install.rdf
  rm -rv $1/chrome/$1/locale/$1/global-platform/{mac,win}

  cd $1
  zip -r langpack-$1@iceape.mozilla.org.xpi .
  mv -v langpack-$1@iceape.mozilla.org.xpi $srcdir
  cd ..
  rm -rv $1

  install -vDm644 langpack-$1@iceape.mozilla.org.xpi \
    "$pkgdir/usr/lib/iceape-$pkgver/extensions/langpack-$1@iceape.mozilla.org.xpi"
}

sha256sums=('21473f12638f447e573ce26d02297f9d966f61e04c5fcbb7fc30919a26a6c94b'
            'c01f71da0ed60a9a1e31325ca79ad3bf629496d42adb1871de756faa658db420'
            'd49655d6c7e6bbc16158d77a075f54b15b5740a6fe0cf9c6ea08df72ca44bcad'
            '41d8ae62c7af6b5e7168ba26a0b32e34e41a0357ed6e83a2097307c9b2e10afc'
            'dc8c43b153d063e099a50399b07069c4e00550f2826ad59d0eb14f6247801c03'
            '2118452fa650182eae694100711634021b7b1b574e285bd2f94902a9aa8533c2'
            '289803bc8d1669aa8dc116e55ffbef60a611002c39dbe9e461ad3546d82043d5'
            '7cd996abf7027189f6c3fd09501331b1bcf06a61f596cd7042d2a2a66b58e0e2'
            '6204072196d5ef65cfd5a380d7a985f225f17b8bf5c945e7828ca33cdb09b2da'
            'a12a02029fef8caa33a99c7bd254bcacf3825b1edbbbc7a2775a8f5a1756425f'
            '6b7d78e35df5609cdbc944cc4a36fade59d9d29ba761d31969b20be13eebff0e'
            'f9c92da4f70391413c4be4255332add2fa60a54d8e42c3205badffc4579717da'
            'fe0d89ba946aff3ff90e6751491a64acf381d2fb176ed10270d113bc572e22f2'
            'c1732389c3d532ca50152fda28495387e66c6ab9cfcda0b607936e9601549310'
            'fa90086e2d3cc968010c222e58d5e4b465c2c374e07223191483b574db772999'
            '20b888b8f9c2c2115e8a3a2157d6f8da353c484d573da0d347ffffd41f99bc76'
            'a13b872cf8ecc3cfaf1d8fc5e9a136ba4abd8ae07f4fff15e6dbe9fdd9e5ad7c'
            '65fd240cdad3bc4808f0eb35ccf7cfeb9c5c69ba28d446fce91f225b0161ce97'
            '859ee3e4733f944af91d06051cd99fb78f1bb7d60f012e8cf433cf65fb0d17a3'
            'bcd3b61379bbd1c28974f4609aefa25ece6b5f64715c4cb52b6eafffb60f23e6'
            '9a7280be0ae9bdf0f21ad89749cbd050dcac588989c33b016bf79496ad3660df'
            '6e880ed775dbf46eb62e3ac9b8a55091790a451f86776aa5ba0de1945d8a23aa'
            '00cc6c894fc6dab4a22e9d38fb6037850f8e57a13f8150d64e8faf3878f204c8'
            '7be70081c211aed53e98228ed9f9d20741f227bbafb696acf44a5eae20a286f1'
            '9ad1066cb6cc07a49bbd0b2e8295db65e490a07af7c36485ae607d788817ec5e'
            'f70af092108244bc70d3daa53fd41bd3a47c1af518afeca2b6f431952643c6e7'
            '4ee82e2d89fd9846b4fc9465797c2f04facea76b10bf00d82ade5a581b6c5c59'
            '9d5e12b135b8157ab0febe7d2253466cc90ee410322234ebe23a3b4de83461b3'
            '6b4bed5fd385b1666579cf69cf094f7f81e4533be62915b02a9154ed9bbed6fe'
            '7cdb2dc31da908a506fca78c93008cf1b6ce9ef3dddb0fcb38b383bf9e5be556'
            'a3ae379666ff757e0424918491ae1aa710d08aa586d0fd4526bf4dd838c1461c')