# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>

_pkgbase=iceape
pkgbase=$_pkgbase-l10n

epoch=1
pkgver=2.49.1
pkgrel=1
arch=(any)

pkgdesc="Language pack for ${_pkgbase^}."
url="https://wiki.parabola.nu/$_pkgbase"
license=(MPL GPL)

depends=("$_pkgbase=$epoch:$pkgver")
makedepends=(unzip zip)

_languages=(
  'cs     "Czech"'
  'de     "German"'
  'en-GB  "English (British)"'
  'en-US  "English (American)"'
  'es-AR  "Spanish (Argentina)"'
  'es-ES  "Spanish (Spain)"'
  'fr     "French"'
  'hu     "Hungarian"'
  'it     "Italian"'
  'ja     "Japanese"'
  'lt     "Lithuanian"'
  'nb-NO  "Norwegian"'
  'nl     "Dutch"'
  'pl     "Polish"'
  'pt-PT  "Portuguese (Portugal)"'
  'ru     "Russian"'
  'sk     "Slovak"'
  'sv-SE  "Swedish"'
  'zh-CN  "Chinese (Simplified)"'
  'zh-TW  "Chinese (Traditional)"'
)

pkgname=()
source=('brand.dtd' 'brand.properties' 'communicator-region.properties' 'editor-region.properties' 'messenger-region.properties' 'navigator-region.properties')
_url=https://ftp.mozilla.org/pub/seamonkey/releases/$pkgver/langpack

for _lang in "${_languages[@]}"; do
  _locale=${_lang%% *}
  _pkgname=$pkgbase-${_locale,,}

  pkgname+=($_pkgname)
  source+=("$pkgbase-$pkgver-$_locale.xpi::$_url/seamonkey-$pkgver.$_locale.langpack.xpi")
  eval "package_$_pkgname() {
    _package $_lang
  }"
done

# Don't extract anything
noextract=(${source[@]%%::*})

_package() {
  pkgdesc="$2 language pack for Debian Iceape."
  replaces=(iceape-i18n-${1,,})
  conflicts=(iceape-i18n-${1,,})
  provides=(iceape-i18n-${1,,})

  unzip iceape-l10n-$pkgver-$1.xpi -d $1
  rm -v iceape-l10n-$pkgver-$1.xpi
  install -vDm644 $srcdir/brand.dtd $1/chrome/$1/locale/$1/branding
  install -vDm644 $srcdir/brand.properties $1/chrome/$1/locale/$1/branding
  install -vDm644 $srcdir/navigator-region.properties $1/chrome/$1/locale/$1/navigator-region/region.properties
  install -vDm644 $srcdir/messenger-region.properties $1/chrome/$1/locale/$1/messenger-region/region.properties
  install -vDm644 $srcdir/communicator-region.properties $1/chrome/$1/locale/$1/communicator-region/region.properties
  install -vDm644 $srcdir/editor-region.properties $1/chrome/$1/locale/$1/editor-region/region.properties
  sed -i -e 's/seamonkey/iceape/' $1/install.rdf
  rm -rv $1/chrome/$1/locale/$1/global-platform/{mac,win}

  cd $1
  zip -r langpack-$1@iceape.mozilla.org.xpi .
  mv -v langpack-$1@iceape.mozilla.org.xpi $srcdir
  cd ..
  rm -rv $1

  install -vDm644 langpack-$1@iceape.mozilla.org.xpi \
    "$pkgdir/usr/lib/iceape-$pkgver/extensions/langpack-$1@iceape.mozilla.org.xpi"
}

sha256sums=('21473f12638f447e573ce26d02297f9d966f61e04c5fcbb7fc30919a26a6c94b'
            'c01f71da0ed60a9a1e31325ca79ad3bf629496d42adb1871de756faa658db420'
            'd49655d6c7e6bbc16158d77a075f54b15b5740a6fe0cf9c6ea08df72ca44bcad'
            '41d8ae62c7af6b5e7168ba26a0b32e34e41a0357ed6e83a2097307c9b2e10afc'
            'dc8c43b153d063e099a50399b07069c4e00550f2826ad59d0eb14f6247801c03'
            '2118452fa650182eae694100711634021b7b1b574e285bd2f94902a9aa8533c2'
            '3da0bd7a341a90d5d10348ea53be7ffa3935202919a6d0aea59e69593499e246'
            'c5d997ed331867310dbe3468a6ea14ed327681015b62d61c021b433376ec2ebd'
            '6a168ce1d5e5a6d5e4036f74dada7eac91f0feef6d53165afde30c9f39de643e'
            '046b40b3231073c08975c8608ffd25c0d30ae1377ddae07916c6e859b44a2605'
            'd34c3ab2145d0829c814ce96b51c63c30c925e5c5a84810d411777be059d2cbd'
            '7fce4de8e1160996af38838093710d9e8a6c9f16f1a05e1b76c2778586fb643f'
            '5d32cebf47cea1a6c1cf20da828c4d2f944aa8f2252231d341dd292001fbdf55'
            '5795275d5eba01fe8c48af7f4f661ef5f3e7263f55029c2364a53f9288064401'
            '9c8726b46dc3feaaf014ae142aac7d00c3d7eb4cc11157178c1fc265cd021807'
            '2e7279bd818493bc3ba34352458aeb8d4b27499fa776683e97d0cf3da9f2cdb2'
            'f80892e20e5aad5c97b6c748d36fae3d75174d0164b3796ac45aaa1a5e3432ba'
            'fbbad6d23cb93531f7feb37e68e641a9926ec0f97e8223a71e7fc1fddb068f0e'
            '6641ac30d2cfc6be47aeb92ee796924697be5a54bb384c4196d035f794d90a36'
            '704d1836d6d9b39224b6beb63320b636f45919bd54833996c34ad5bb7144edc7'
            '7d04419a91c82e3e0c5c5e054e757bf1fea6ea9cac2080c8e4c6f2a9e2f803ec'
            '0b125d063e304a5cab261c4a749ec6140ecb61c3c3069f1b0bbb47962b9d4a97'
            '944dabb4e4b177cf43a4304e6d89a8bbf1c5b9b67edf44b20240ff3e406a3196'
            '1d047f07347acd38fd3c2a726f98697b43294969772f4540d171ade622ed2d7e'
            'b815362ac40fd7928e4f76344e9472225e556751b0fe9babbf4a7462ed8d3264'
            'c08143641eb99e20df9beff3a0a9e1645c7e67d63eb18bc0314a612866cd7d43')