# $Id: PKGBUILD 167398 2016-03-18 12:07:30Z alucryd $
# Maintainer (Arch): Maxime Gauduin <alucryd@archlinux.org>
# Contributor (Arch): TingPing <tingping@tingping.se>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=hexchat
pkgver=2.12.0
pkgrel=1.parabola1
pkgdesc='A popular and easy to use graphical IRC (chat) client, without nonfree browser reference'
arch=('i686' 'x86_64')
url='http://hexchat.github.io/'
license=('GPL')
depends=('dbus-glib' 'desktop-file-utils' 'gdk-pixbuf2' 'glib2' 'glibc' 'gtk2'
         'libcanberra' 'libnotify' 'libproxy' 'openssl' 'pango' 'pciutils')
makedepends=('intltool' 'iso-codes' 'perl' 'python')
optdepends=('enchant: Spell check'
            'perl: Perl plugin'
            'python: Python plugin')
install="${pkgname}.install"
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
source=("http://dl.hexchat.net/${pkgname}/${pkgname}-${pkgver}.tar.xz")
sha256sums=('c2072f97510c0fe6ecfb0878750d27179633e08199066972fa00e5a23e67d69d')

prepare() {
  cd ${pkgname}-${pkgver}

# Remove nonfree browser references
  sed -i '\|NAME Open Link| s|Firefox|Iceweasel|' src/common/hexchat.c
  sed -i '\|NAME Open Link| s|firefox -new-window %s\\n\\n";|iceweasel -new-window %s\\n\\n"\\\n		"NAME Open Link in a new Icecat Window\\n"		"CMD !icecat -new-window %s\\n\\n";|' src/common/hexchat.c
}

build() {
  cd ${pkgname}-${pkgver}

  ./configure \
    --prefix='/usr' \
    --enable-python='python3' \
    --enable-textfe
  make
}

package() {
  cd ${pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et: