# $Id: PKGBUILD 91125 2013-05-19 21:58:09Z alucryd $
# Maintainer: Maxime Gauduin <alucryd@gmail.com>
# Contributor: TingPing <tingping@tingping.se>
# Maintainer (Parabola): André Silva <emulatorman@lavabit.com>

_pkgname=hexchat
pkgname=hexchat-libre
pkgver=2.9.5
pkgrel=5
pkgdesc="A popular and easy to use graphical IRC (chat) client, without nonfree browser reference (Parabola rebranded)"
arch=('i686' 'x86_64' 'mips64el')
url="http://www.hexchat.org/"
license=('GPL')
depends=('dbus-glib' 'desktop-file-utils' 'hicolor-icon-theme' 'libnotify' 'libproxy' 'libsexy' 'pciutils')
makedepends=('perl' 'python2')
optdepends=('enchant: Spell check'
            'perl: Perl plugin'
            'python2: Python plugin')
options=('!libtool')
install=${_pkgname}.install
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
source=("http://dl.hexchat.org/hexchat/hexchat-${pkgver}.tar.xz"
        'remove-non-free-suggestion.patch'
        'no-firefox.patch')
sha256sums=('11dfd0fbfb88d8dbb38f631fab8a7dffbb179f7f7dafe316953ed6f513ac623d'
            '61040cb2a369b1b8801509c88019d68d1ab4c2505b1dfd859de1a4c22503f02d'
            'de338821e1a8790a6fbdba2ce41d323002f51e3ae3e99ee8d815fcf087197e45')

build() {
  cd "${srcdir}"/${_pkgname}-${pkgver}

# Rebrand to Parabola
  sed -i -e 's#ArchLinux#Parabola GNU/Linux-libre#' plugins/sysinfo/parse.c

# Remove nonfree browser references
  patch -p1 -i "${srcdir}/remove-non-free-suggestion.patch"
  patch -p1 -i "${srcdir}/no-firefox.patch"

# Build
  ./autogen.sh
  ./configure --prefix=/usr --enable-{shm,spell=libsexy,textfe}
  make
}

package() {
  cd "${srcdir}"/${_pkgname}-${pkgver}

# Install
  make DESTDIR="$pkgdir" install

# IRC Mime Types
  desktop-file-edit --add-mime-type='x-scheme-handler/irc;x-scheme-handler/ircs' --set-key=Exec --set-value='sh -c "hexchat --existing --url %u || exec hexchat"' "$pkgdir/usr/share/applications/hexchat.desktop"
}

# vim: ts=2 sw=2 et: