# $Id: PKGBUILD 116500 2014-07-28 22:25:29Z alucryd $
# Maintainer (Arch): Maxime Gauduin <alucryd@gmail.com>
# Contributor (Arch): TingPing <tingping@tingping.se>
# Maintainer: André Silva <emulatorman@parabola.nu>

_pkgname=hexchat
pkgname=hexchat-libre
pkgver=2.10.1
pkgrel=1
pkgdesc='A popular and easy to use graphical IRC (chat) client, without nonfree browser reference (Parabola rebranded)'
arch=('i686' 'x86_64' 'mips64el')
url='http://hexchat.github.io/'
license=('GPL')
depends=('dbus-glib' 'desktop-file-utils' 'gtk2' 'libcanberra' 'libnotify' 'libproxy' 'pciutils')
makedepends=('intltool' 'iso-codes' 'perl' 'python')
optdepends=('enchant: Spell check'
            'perl: Perl plugin'
            'python: Python plugin')
install="${_pkgname}.install"
replaces=($_pkgname)
conflicts=($_pkgname)
provides=($_pkgname=$pkgver)
source=("http://dl.hexchat.org/${_pkgname}/${_pkgname}-${pkgver}.tar.xz")
sha256sums=('ffccee6a3470d2f9539e75bd0dd2e3f35c65737004cb02e6d2106c1d5dcde9a9')

prepare() {
  cd ${_pkgname}-${pkgver}

  sed 's/CFLAGS="$PERL_CFLAGS"/CFLAGS="$PERL_CFLAGS -fuse-ld=gold"/' -i configure

# Rebrand to Parabola
  sed -i 's#ArchLinux#Parabola GNU/Linux-libre#' plugins/sysinfo/parse.c

# Remove nonfree browser references
  sed -i '\|NAME Open Link| s|Firefox|Iceweasel|' src/common/hexchat.c
  sed -i '\|NAME Open Link| s|firefox -private %s\\n\\n";|iceweasel -private %s\\n\\n"\\\n		"NAME Open Link in Private Icecat Window\\n"		"CMD !icecat -private %s\\n\\n";|' src/common/hexchat.c
}

build() {
  cd ${_pkgname}-${pkgver}

  ./configure --prefix='/usr' --enable-{perl,python='python3.4',textfe}
  make
}

package() {
  cd ${_pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install
}

# vim: ts=2 sw=2 et: