# Maintainer (Arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor (Arch): Sam Stuewe <halosghost at archlinux dot info>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=hashcat
pkgver=3.30
pkgrel=1.parabola1
pkgdesc='Multithreaded advanced password recovery utility, without nonfree libxnvctrl recommendation'
url='https://hashcat.net/hashcat'
arch=('i686' 'x86_64' 'armv7h')
depends=('gmp' 'opencl-icd-loader')
makedepends=('opencl-headers')
license=('MIT')
source=(https://hashcat.net/files/${pkgname}-${pkgver}.tar.gz{,.asc})
sha512sums=('9c87978c72a595babec964e0c9ee506fdc24c870966dabf3854996808c910af369329e95932e1833a917a316441a83d6ba5cfff0f54bb5d8f9af6981243746cb'
            'SKIP')
validpgpkeys=('A70833229D040B4199CC00523C17DA8B8A16544F') # Hashcat signing key <signing@hashcat.net>

prepare() {
  cd ${pkgname}-${pkgver}
  sed 's|-Wl,-rpath .||g' -i src/Makefile
}

build() {
  cd ${pkgname}-${pkgver}
  make PREFIX=/usr
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" PREFIX=/usr install
  install -Dm 644 docs/license.txt "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}

# vim: ts=2 sw=2 et: