# $Id: PKGBUILD 212780 2014-05-15 06:02:26Z tpowa $
# Maintainer (Arch): Tom Gundersen <teg@jklm.no>
# Contributor (Arch): Tobias Powalowski <tpowa@archlinux.org>
# Contributor (Arch): Keshav P R <(the.ridikulus.rat) (aatt) (gemmaeiil) (ddoott) (ccoomm)>
# Contributor (Arch):  Mantas Mikulėnas <grawity@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=gummiboot
pkgver=48
pkgrel=1.parabola3
pkgdesc="Simple UEFI Boot Manager (Parabola rebranded)"
url="http://freedesktop.org/wiki/Software/gummiboot"
arch=('x86_64' 'i686')
license=('LGPL2.1')
makedepends=('gnu-efi-libs' 'docbook-xsl' 'git')
depends=('util-linux')
conflicts=('gummiboot-efi' "${pkgname}-parabola")
provides=('gummiboot-efi')
replaces=('gummiboot-efi' "${pkgname}-parabola")
options=('!strip' '!makeflags')
source=("git://anongit.freedesktop.org/$pkgname#tag=$pkgver"
        'loader.conf'
        'parabola.conf'
        'splash-parabola.bmp')
install=gummiboot.install
md5sums=('SKIP'
         '3d700d13aec5ab1b78a921eaf22e5bfa'
         '36ee74767ac8734dede1cbd0f4f275d7'
         'db7c5e4aaa501c1af4301e011f4f5966')

build() {
	cd ${srcdir}/${pkgname}

	./autogen.sh
	./configure --sysconfdir=/etc  --with-efi-ldsdir=/usr/lib --libexecdir=/usr/lib --libdir=/usr/lib
	
	make
}

package() {
	## Install gummiboot example configuration files (can go away with systemd's kernel-install)
	install -D -m0644 "${srcdir}/loader.conf" "${pkgdir}/usr/lib/gummiboot/loader/loader.conf"
	install -D -m0644 "${srcdir}/parabola.conf" "${pkgdir}/usr/lib/gummiboot/loader/entries/parabola.conf"

	## ship an Parabola GNU/Linux-libre boot splash (still has to be dropped in manually to take effect)
	install -D -m0644 "${srcdir}/splash-parabola.bmp" "${pkgdir}/usr/lib/gummiboot/splash-parabola.bmp"

	cd ${srcdir}/${pkgname}

	make DESTDIR="${pkgdir}" install
}