# $Id$
# Maintainer: Tom Gundersen <teg@jklm.no>
# Contributor: Tobias Powalowski <tpowa@archlinux.org>
# Contributor: Keshav P R <(the.ridikulus.rat) (aatt) (gemmaeiil) (ddoott) (ccoomm)>
# Contributor:  Mantas Mikulėnas <grawity@gmail.com>

pkgname="gummiboot"
pkgver="29"
pkgrel="1.1"
pkgdesc="Simple text-mode UEFI Boot Manager, Parabola rebranded"
url="http://freedesktop.org/wiki/Software/gummiboot"
arch=('x86_64' 'i686' 'mips64el')
license=('LGPL2.1')
makedepends=('gnu-efi-libs' 'docbook-xsl')
depends=('util-linux')
conflicts=('gummiboot-efi')
provides=('gummiboot-efi')
replaces=('gummiboot-efi')
options=('!strip')
source=("ftp://ftp.archlinux.org/other/packages/${pkgname}/${pkgname}-${pkgver}.tar.xz"
        'loader.conf'
        'parabola.conf')
install="gummiboot.install"

build() {
	cd "${srcdir}/${pkgname}-${pkgver}/"

	./autogen.sh
	./configure --sysconfdir=/etc --libexecdir=/usr/lib --libdir=/usr/lib
	
	make
}

package() {
	## Install gummiboot example configuration files (can go away with systemd's kernel-install)
	install -D -m0644 "${srcdir}/loader.conf" "${pkgdir}/usr/lib/gummiboot/loader/loader.conf"
	install -D -m0644 "${srcdir}/parabola.conf" "${pkgdir}/usr/lib/gummiboot/loader/entries/parabola.conf"

	cd "${srcdir}/${pkgname}-${pkgver}/"
	make DESTDIR="${pkgdir}" install
}
md5sums=('7e133411b805ce6fb5dd3e3bd08b88a2'
         '3d700d13aec5ab1b78a921eaf22e5bfa'
         '9f770584795496c0e3409679eaf7be3b')