# $Id: PKGBUILD 289453 2017-02-23 20:23:57Z heftig $
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>

pkgname=gst-plugins-bad
pkgver=1.12.3
pkgrel=1.parabola1
pkgdesc="GStreamer Multimedia Framework Bad Plugins, without nonfree faac support"
url="https://gstreamer.freedesktop.org/"
arch=(i686 x86_64 armv7h)
license=(LGPL)
depends=(mjpegtools gst-plugins-base-libs curl chromaprint libmms faad2 celt libdca libdvdnav
         libmodplug libgme wayland libofa openjpeg2 libwebp libsrtp gnutls glu sbc rtmpdump
         libgudev graphene schroedinger libexif libdvdread libvdpau libmpeg2 wildmidi ladspa
         openal libusb vulkan-icd-loader libfdk-aac soundtouch spandsp neon
         webrtc-audio-processing libdc1394 libmpcdec zvbi)
makedepends=(python gobject-introspection gtk-doc git autoconf-archive vulkan-headers
             gtk3 clutter librsvg libtiger qt5-declarative qt5-x11extras qt5-wayland zbar
             fluidsynth lilv opencv openexr)
makedepends_x86_64=(valgrind)
makedepends_i686=("${makedepends_x86_64[@]}")
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
_commit=8f66ff25f9cabc170c57d75a74984103c7fcb965  # tags/1.12.3
source=("git+https://anongit.freedesktop.org/git/gstreamer/gst-plugins-bad#commit=$_commit"
        "gst-common::git+https://anongit.freedesktop.org/git/gstreamer/common")
sha256sums=('SKIP'
            'SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname

  git submodule init
  git config --local submodule.common.url "$srcdir/gst-common"
  git submodule update

  sed -i 's/cmu_us_kal/&16/g' configure.ac ext/flite/gstflitetestsrc.c

  # temporary fix to get 1.12.3 to build on Parabola
  sed -i 's/openjpeg-2.2/openjpeg-2.3/' ext/openjpeg/gstopenjpeg.h

  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname

  case "$CARCH" in
    i686|x86_64) extra="--enable-gtk-doc" ;;
    arm*|aarch64) extra="" ;;
    *) extra="" ;;
  esac

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib \
    --with-package-name="GStreamer Bad Plugins (Parabola GNU/Linux-libre)" \
    --with-package-origin="https://www.parabola.nu/" \
    --with-gtk=3.0 \
    --enable-experimental --disable-static $extra

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

check() {
  cd $pkgname
  # bad tests are bad
  #make -k check || :
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}