# $Id: PKGBUILD 273962 2016-08-19 13:57:36Z jgc $
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: Márcio Silva <coadde@parabola.nu>

pkgname=gst-plugins-bad
pkgver=1.8.3
pkgrel=1.parabola1
pkgdesc="GStreamer Multimedia Framework Bad Plugins, without nonfree faac support"
arch=(i686 x86_64 armv7h)
license=(LGPL)
url="http://gstreamer.freedesktop.org/"
depends=(mjpegtools gst-plugins-base-libs curl chromaprint libmms faad2 celt libdca
         soundtouch spandsp libdvdnav libmodplug libgme wayland neon libofa fluidsynth
         openjpeg2 libwebp libsrtp gnutls wildmidi glu sbc rtmpdump libgudev graphene)
makedepends=(schroedinger libexif libdvdread libvdpau libmpeg2 python valgrind wildmidi librsvg
             gobject-introspection gtk-doc gtk3 clutter libtiger ladspa openal libusb
             qt5-declarative qt5-x11extras qt5-wayland vulkan-headers vulkan-icd-loader
             zbar)
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
options=(!emptydirs)
source=(${url}/src/$pkgname/$pkgname-$pkgver.tar.xz
        wildmidi-0.4.patch)
sha256sums=('7899fcb18e6a1af2888b19c90213af018a57d741c6e72ec56b133bc73ec8509b'
            'b234c5d1a8b33342d9f807a46c26623e21f3d1b33a9b2903a41fadd53e0cac47')

prepare() {
  cd $pkgname-$pkgver
  patch -Np1 -i ../wildmidi-0.4.patch
  autoreconf -vi
}

build() {
  cd $pkgname-$pkgver

  # disable GL and GLX on armv7h
  [[ "$CARCH" = "armv7h" ]] && extra="--disable-gl --disable-glx --enable-gles2"

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --disable-static --enable-experimental --enable-gtk-doc \
    --with-package-name="GStreamer Bad Plugins (Parabola GNU/Linux-libre)" \
    --with-package-origin="https://www.parabola.nu/" \
    --with-gtk=3.0 $extra

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

check() {
  cd $pkgname-$pkgver
  # don't have a camera for the camerabin test
  make -k check || :
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
}