# $Id: PKGBUILD 128936 2015-03-08 18:57:19Z bgyorgy $
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Stefano Facchini <stefano.facchini@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Daniel Milewski <niitotantei@gmail.com>

pkgname=gnome-boxes
pkgver=3.14.3.1
pkgrel=1.parabola1
pkgdesc="Simple GNOME 3 application to access remote or virtual systems, without nonfree system logos"
arch=('i686' 'x86_64' 'mips64el')
url="https://wiki.gnome.org/Apps/Boxes"
license=('LGPL')
conflicts=(${pkgname}-libre)
replaces=(${pkgname}-libre)
depends=('clutter-gtk' 'gtk-vnc' 'libarchive' 'libosinfo' 'libsoup' 'libvirt-glib'
         'spice-gtk3' 'libtracker-sparql' 'qemu' 'cdrkit' 'mtools' 'dconf'
         'gnome-themes-standard')
makedepends=('gobject-introspection' 'intltool' 'itstool' 'spice-protocol' 'vala')
install=$pkgname.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/3.14/$pkgname-$pkgver.tar.xz
        libre.patch)
sha256sums=('048df41ce1bcece1d89dfddcb571ed17dfa7f614929cd63f3079d14c66c10f24'
            '1847d0b7886f32fe64392f1acebc28eee35466311ae00f17a6955b16322c6456')

prepare() {
  cd $pkgname-$pkgver

  patch -Np1 -i "$srcdir/libre.patch"
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib/$pkgname \
              --disable-static --disable-schemas-compile --enable-smartcard
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}