# $Id: PKGBUILD 119632 2014-09-26 21:39:45Z bgyorgy $
# Maintainer (Arch): Balló György <ballogyor+arch at gmail dot com>
# Contributor (Arch): Stefano Facchini <stefano.facchini@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Daniel Milewski <niitotantei@gmail.com>

pkgname=gnome-boxes
pkgver=3.14.0
pkgrel=1.parabola1
pkgdesc="Simple GNOME 3 application to access remote or virtual systems, without nonfree system logos"
arch=('i686' 'x86_64' 'mips64el')
url="https://wiki.gnome.org/Apps/Boxes"
license=('LGPL')
conflicts=(${pkgname}-libre)
replaces=(${pkgname}-libre)
depends=('clutter-gtk' 'gtk-vnc' 'libarchive' 'libosinfo' 'libsoup' 'libvirt-glib'
         'spice-gtk3' 'libtracker-sparql' 'qemu' 'cdrkit' 'mtools' 'dconf'
         'gnome-themes-standard')
makedepends=('gobject-introspection' 'intltool' 'itstool' 'spice-protocol' 'vala')
install=$pkgname.install
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.xz
        libre.patch)
sha256sums=('97d3543b3686737246b4b5791ad70b5358a299050ad9e58ae708a123c142945d'
            '2a93935ba94b9f327645a92f11d1a3d23cbeab8e5c800e414c6762181f51d4c0')

prepare() {
  cd $pkgname-$pkgver

  patch -Np1 -i "$srcdir/libre.patch"
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var --libexecdir=/usr/lib/$pkgname \
              --disable-static --disable-schemas-compile --enable-smartcard
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}