# $Id$
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: Isaac David <isacdaavid@at@isacdaavid@dot@info>

# parabola changes and rationale:
#  - removed unace recommendation

pkgname=file-roller
pkgver=3.28.0
pkgrel=1.parabola1
pkgdesc="Create and modify archives, without nonfree unace recommendation"
url="https://wiki.gnome.org/Apps/FileRoller"
arch=(x86_64 i686 armv7h)
license=(GPL)
depends=(gtk3 dconf libarchive file json-glib libnotify zip unzip)
makedepends=(intltool itstool docbook-xsl gnome-common git libnautilus-extension
             meson)
optdepends=('p7zip: 7z, arj, exe and encrypted zip files support'
            'unrar: better RAR archive support'
            'lrzip: lrzip archive support')
groups=(gnome)
_commit=be8499528b415f66b60b3332a976563d62c58eec  # tags/3.28.0^0
source=("git+https://git.gnome.org/browse/file-roller#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

build() {
  arch-meson $pkgname build
  ninja -C build
}

package() {
  DESTDIR="$pkgdir" ninja -C build install
}