# $Id: PKGBUILD 273892 2016-08-17 20:45:37Z heftig $
# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>

pkgname=file-roller
pkgver=3.20.3
pkgrel=1.parabola1
pkgdesc="Create and modify archives, without nonfree unace and unrar recommendation"
url="https://wiki.gnome.org/Apps/FileRoller"
arch=(i686 x86_64 armv7h)
license=(GPL)
depends=(gtk3 dconf libarchive file json-glib libnotify zip unzip)
makedepends=(intltool libnautilus-extension itstool docbook-xsl)
optdepends=('p7zip: 7z, arj, exe and encrypted zip files support'
            'lrzip: lrzip archive support')
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
groups=(gnome-extra)
options=(!emptydirs)
source=(https://download.gnome.org/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('6b5c2de4c6bd52318cacd2a398cdfa45a5f1df8a77c6652a38a6a1d3e53644e9')

build() {
  cd $pkgname-$pkgver

  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
    --libexecdir=/usr/lib/$pkgname --disable-static --disable-schemas-compile

  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}