# Maintainer (Arch): Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: Isaac David <isacdaavid@at@isacdaavid@dot@info>

# parabola changes and rationale:
#  - removed unace and unrar recommendation

pkgname=file-roller
pkgver=3.32.1
pkgrel=1
pkgrel+=.par1
pkgdesc="Create and modify archives"
pkgdesc+=", without nonfree unace and unrar recommendation"
url="https://wiki.gnome.org/Apps/FileRoller"
arch=(x86_64)
arch+=(i686 armv7h)
license=(GPL)
depends=(gtk3 dconf libarchive file json-glib libnotify zip unzip)
makedepends=(yelp-tools git libnautilus-extension meson appstream-glib)
optdepends=('p7zip: 7z, arj, exe and encrypted zip files support'
            'lrzip: lrzip archive support')
groups=(gnome)
_commit=c892c8c576d026fe87c17775b033e3e73f3d3ac5  # master
source=("git+https://gitlab.gnome.org/GNOME/file-roller.git#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  git tag -f 3.32.1 c892c8c576d026fe87c17775b033e3e73f3d3ac5  # fixup missing tag
}

build() {
  arch-meson $pkgname build
  ninja -C build
}

check() {
  meson test -C build
}

package() {
  DESTDIR="$pkgdir" meson install -C build
}