# $Id: PKGBUILD 241912 2015-07-09 15:06:26Z heftig $
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgname=epiphany
pkgver=3.16.3
pkgrel=1.parabola1
install=epiphany.install
pkgdesc="A GNOME web browser based on the WebKit rendering engine, with DuckDuckGo HTML support"
arch=('i686' 'x86_64')
license=('GPL')
depends=('libsoup' 'libnotify' 'gsettings-desktop-schemas' 'webkit2gtk' 'nss' 'iso-codes' 'dconf' 'desktop-file-utils' 'gcr' 'gnome-desktop' 'libwnck3' 'gnome-themes-standard')
makedepends=('intltool' 'itstool' 'docbook-xml' 'startup-notification' 'gobject-introspection')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
options=('!emptydirs')
groups=('gnome')
url="https://wiki.gnome.org/Apps/Web"
source=(http://ftp.gnome.org/pub/GNOME/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz)
sha256sums=('d527f1770779ec22d955aeb13b148a846a26144e433ff0480c981af80e2390b1')

prepare() {
  cd $pkgname-$pkgver

  # Replace DuckDuckGo to DuckDuckGo HTML
  sed -i 's|duckduckgo[.]com|duckduckgo.com/html|g' $(grep -rlI 'duckduckgo[.]com')

  # Replace Google support to DuckDuckGo HTML
  sed -i 's|http://www[.]google[.]com/search?q=%s[&]ie=UTF-8[&]oe=UTF-8|https://duckduckgo.com/html/?q=search|g' $(grep -rlI 'http://www[.]google[.]com/search?q=%s&ie=UTF-8&oe=UTF-8')
  sed -i '\|a quoted string should be searched|d' $(grep -rlI 'a quoted string should be searched')
  sed -i 's|http://www[.]google[.]com/search?q=%s[&]amp;ie=UTF-8[&]amp;oe=UTF-8|https://duckduckgo.com/html/?q=%s|g' $(grep -rlI 'http://www[.]google[.]com/search')
  sed -i 's|http://www[.]google[.]com|https://duckduckgo.com/html|g' $(grep -rlI 'google[.]com')
  sed -i 's|http://google[.]com|https://duckduckgo.com/html|g' $(grep -rlI 'google[.]com')
  sed -i 's|mail[.]google[.]com|mail.com|g' $(grep -rlI 'mail[.]google[.]com')
  sed -i 's|google[.]com|duckduckgo.com/html|g' $(grep -rlI 'google[.]com')
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --libexecdir=/usr/lib/$pkgname

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install
}