# $Id$
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Márcio Silva <coadde@hyperbola.info>

# parabola changes and rationale:
#  - rebranded to parabola
#  - switched default searchengine to duckduckgo

pkgname=epiphany
pkgver=3.28.1
pkgrel=1.parabola1
pkgdesc="A GNOME web browser based on the WebKit rendering engine, with DuckDuckGo HTML support"
url="https://wiki.gnome.org/Apps/Web"
arch=(x86_64 i686 armv7h)
license=(GPL)
depends=(webkit2gtk gcr icu)
makedepends=(itstool docbook-xml startup-notification lsb-release
             gobject-introspection yelp-tools appstream-glib git meson)
groups=(gnome)
_commit=eb7a411968ecb42a49a4cfd108df036d8fdb034e  # tags/3.28.1^0
source=("git+https://git.gnome.org/browse/epiphany#commit=$_commit"
        pluginsdir.diff
        libre.patch)
sha256sums=('SKIP'
            'b6c8ee6ace934c053f2fd89758e0b587cb8953c6b0246c1359aecaae4de70289'
            '8cee8e5f896ce12832d50e7ab97ef16165d70d135018742e0f5bc15507d4e708')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  patch -Np1 -i ../pluginsdir.diff
  patch -Np1 -i ../libre.patch
}

build() {
  arch-meson $pkgname build \
    -D distributor_name="Parabola GNU/Linux-libre"
  ninja -C build
}

package() {
  DESTDIR="$pkgdir" ninja -C build install
}