# $Id: PKGBUILD 288002 2017-02-03 23:55:29Z heftig $
# Maintainer (Arch): Jan de Groot <jgc@archlinux.org>
# Maintainer (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

pkgname=epiphany
pkgver=3.24.3
pkgrel=1.parabola1
pkgdesc="A GNOME web browser based on the WebKit rendering engine, with DuckDuckGo HTML support"
url="https://wiki.gnome.org/Apps/Web"
arch=(i686 x86_64 armv7h)
license=(GPL)
depends=(webkit2gtk gcr gnome-desktop icu)
makedepends=(intltool itstool docbook-xml startup-notification lsb-release
             gobject-introspection yelp-tools autoconf-archive appstream-glib git)
groups=(gnome)
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)
_commit=43489a7d54b89a45709fadd6a90d0e99cf0dc45d  # tags/3.24.3^0
source=("git+https://git.gnome.org/browse/epiphany#commit=$_commit"
        "git+https://git.gnome.org/browse/libgd"
        "git+https://git.gnome.org/browse/gvdb"
        pluginsdir.diff
        privacy.patch)
sha256sums=('SKIP'
            'SKIP'
            'SKIP'
            '3bbd4b36e697a3a9165e0b71d5af566fe96a8f1237d854b9dee9a7e0b9fef8e3'
            '4cfef33af39c2292f5a5378154adb94be5937dc065b881b168b5df99557474f1')

pkgver() {
  cd $pkgname
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd $pkgname
  patch -Np1 -i ../pluginsdir.diff
  patch -Np1 -i ../privacy.patch

  git submodule init
  git config --local submodule.libgd.url "$srcdir/libgd"
  git config --local submodule.gvdb.url "$srcdir/gvdb"
  git submodule update

  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd $pkgname
  ./configure --prefix=/usr --sysconfdir=/etc \
      --localstatedir=/var --libexecdir=/usr/lib/$pkgname --enable-compile-warnings=yes

  # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  make
}

package() {
  cd $pkgname
  make DESTDIR="$pkgdir" install
}