# $Id: PKGBUILD 102182 2013-12-06 12:17:23Z giovanni $
# Maintainer: Giovanni Scafora <giovanni@archlinux.org>
# Contributor: Fredrik Hammar <Horney_C86@Hotmail.com>
# Maintainer (Parabola): Márcio Silva <coadde@parabola.nu>

_pkgname=dvdrip
pkgname=dvdrip-libre
pkgver=0.98.11
pkgrel=10.3
pkgdesc="A Gtk frontend for transcode writen in Perl, without opcional hal and nonfree rar vobsub compression support"
arch=('i686' 'x86_64')
license=('custom')
url="http://www.exit1.org/${_pkgname}/"
install=${_pkgname}.install
depends=('perl-gtk2-ex-formfactory' 'transcode' 'imagemagick'
         'perl-libintl-perl' 'desktop-file-utils' 'perl-event-execflow')
optdepends=('xvid4conf: xvid4 configuration tool'
            'lsdvd: Needed for faster DVD TOC reading'
            'mplayer: Needed for subtitle vobsub viewing'
            'mplayer-vaapi: Needed for subtitle vobsub viewing'
            'mplayer2: Needed for subtitle vobsub viewing'
            'ogmtools: Needed for OGG/Vorbis and for chapter progress bar'
            'xine-ui: Can be used to view DVD'\''s/files'
            'fping: Only for cluster mode master')
source=("http://www.exit1.org/${_pkgname}/dist/${_pkgname}-${pkgver}.tar.gz"
        "${_pkgname}.desktop" "libre.patch")
options=('!emptydirs' '!makeflags')
replaces=("${_pkgname}")
conflicts=("${_pkgname}")
provides=("${_pkgname}=${pkgver}")
md5sums=('6dfa4199d451757a37eea233a07da4c0'
         'e91cf411928fd0500d07a0022b4ef546'
         'bc006d3b3447f8b62ae6ba29773a064b')

prepare() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  patch -Np1 -i "$srcdir/libre.patch"
}

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  # install module in vendor directories.
  PERL_MM_USE_DEFAULT=1 perl Makefile.PL INSTALLDIRS=vendor
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  make install DESTDIR="${pkgdir}"

  # remove perllocal.pod and .packlist
  find ${pkgdir} -name perllocal.pod -delete
  find ${pkgdir} -name .packlist -delete

  install -Dm644 ${srcdir}/${_pkgname}.desktop "${pkgdir}/usr/share/applications/${_pkgname}.desktop"
  install -Dm 644 COPYRIGHT "${pkgdir}/usr/share/licenses/${_pkgname}/LICENSE"
}