# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>

pkgname=debootstrap

pkgver=1.0.93
pkgrel=2.parabola1
arch=(any)

pkgdesc="Bootstrap a basic gNewSense and Trisquel system, without Debian support"
url="https://tracker.debian.org/pkg/debootstrap"
license=(GPL)

depends=(wget binutils)
makedepends=(git)
optdepends=('gnupg: check release signatures')
replaces=(${pkgname}-libre)
conflicts=(${pkgname}-libre)

source=("git+https://anonscm.debian.org/git/d-i/debootstrap.git#tag=$pkgver"
        arch-detect.patch
        debootstrap.8
        gnewsense
        trisquel)
sha512sums=('SKIP'
            '824109b2ea138d0dd1a31039a165cb4079da856cb11c664fc5a7f49a42de08ff56a620887d3c0914b69140849799f4473b1f27a05cd14cd60ef2a41627f8d5e1'
            '39795caf3a0fd8bc874d00937580184904cac10c8cdf17b14cc0b5bca9b4732ecedb7161c2fb76f004d270a91396a2e74fa405c96167ab6c5a36553d1da715f0'
            '968ef005bf1f399b3400080b2ba65f1b32c067c49faadc1caa7ee524a85980f0a6625c7b06838e01bbd8b99a496492da77a38f0e17f0a81fc029ee611fe639b6'
            'b192dcbd0d85923ddd97d1094bbcf36edb36a095bfe06e0971707651524f6712c7ab21f733ba6f24e5cbc2e977aec7c52645e41b78d04e45fca65971f89a47a7')

prepare() {
  cd debootstrap

  sed -i 's/sbin/bin/g' Makefile

  # gNewSense/Trisquel defaults
  sed -i 's|export PATH|export PATH="/usr/local/sbin:/usr/local/bin:/usr/sbin:/usr/bin:/sbin:/bin"|' debootstrap

  # Detect Architecture
  patch -p1 -i ../arch-detect.patch

  # Remove Debian files
  rm -v debootstrap.8

  # Add rebranded man
  install -m644 ../debootstrap.8 .

  # Remove Debian scripts
  rm -v scripts/*

  # Add gNewSense script
  install -m644 $srcdir/gnewsense scripts

  # Add Trisquel script
  install -m644 $srcdir/trisquel scripts

  # Enter to scripts dir
  cd scripts

  # Create gNewSense symlinks
  ln -s gnewsense ucclia
  ln -s gnewsense parkes

  # Create Trisquel symlinks
  ln -s trisquel awen
  ln -s trisquel belenos
  ln -s trisquel brigantia
  ln -s trisquel dagda
  ln -s trisquel dwyn
  ln -s trisquel robur
  ln -s trisquel slaine
  ln -s trisquel taranis
  ln -s trisquel toutatis
}

package() {
  cd debootstrap
  make DESTDIR="$pkgdir" install

  install -Dm644 debootstrap.8 "$pkgdir"/usr/share/man/man8/debootstrap.8
}