# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# Contributor: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>
# Contributor: André Silva <emulatorman@hyperbola.info>

pkgname=debootstrap
pkgver=1.0.109
pkgrel=1
pkgrel+=.par1
pkgdesc="Bootstrap a basic gNewSense and Trisquel system, without Debian support"
arch=(any)
license=(GPL)
url="https://tracker.debian.org/pkg/debootstrap"
depends=(wget binutils)
source=("$pkgname-$pkgver.tar.gz::https://github.com/felixonmars/debootstrap/archive/$pkgver.tar.gz"
        arch-detect.patch
        debootstrap.8
        gnewsense
        trisquel)
optdepends=('gnupg: check release signatures')
sha512sums=('8b2cf0ba3e0c672a2375ff323c18c18788e17a4bdf3e03d6b72f956a85b989d3998b89215bc7b99925decbba3c9a5dbeddfc72b9baf7c0571f11559ff8286272'
            '56e25f48027f99f7e720859a9e14fe769b1cbd6227c7a7e27e14c2fea88520109342d6e5b127dc34ce8cc40f46941a0c5157ad35cf8ef9b3e4323877a4b32d97'
            '0b3507756b8f29d19146df3201143ccbd71cfd1f7ef865d184079180612b90c046cabab59fe42d246bfe476ae8fd5c43e81ee2fc3ee06bbc1fc3e75d9f1382ca'
            '968ef005bf1f399b3400080b2ba65f1b32c067c49faadc1caa7ee524a85980f0a6625c7b06838e01bbd8b99a496492da77a38f0e17f0a81fc029ee611fe639b6'
            'b192dcbd0d85923ddd97d1094bbcf36edb36a095bfe06e0971707651524f6712c7ab21f733ba6f24e5cbc2e977aec7c52645e41b78d04e45fca65971f89a47a7')

prepare() {
  cd debootstrap-$pkgver

  sed -i 's/sbin/bin/g' Makefile

  # gNewSense/Trisquel defaults
  sed -i 's|export PATH|export PATH="/usr/local/sbin:/usr/local/bin:/usr/sbin:/usr/bin:/sbin:/bin"|' debootstrap

  # Detect Architecture
  patch -p1 -i ../arch-detect.patch

  # Remove Debian files
  rm -v debootstrap.8

  # Add rebranded man
  install -m644 ../debootstrap.8 .

  # Remove Debian scripts
  rm -v scripts/*

  # Add gNewSense script
  install -m644 $srcdir/gnewsense scripts

  # Add Trisquel script
  install -m644 $srcdir/trisquel scripts

  # Enter to scripts dir
  cd scripts

  # Create gNewSense symlinks
  ln -s gnewsense ucclia
  ln -s gnewsense parkes

  # Create Trisquel symlinks
  ln -s trisquel awen
  ln -s trisquel belenos
  ln -s trisquel brigantia
  ln -s trisquel dagda
  ln -s trisquel dwyn
  ln -s trisquel flidas
  ln -s trisquel robur
  ln -s trisquel slaine
  ln -s trisquel taranis
  ln -s trisquel toutatis
}

package() {
  cd debootstrap-$pkgver
  make DESTDIR="$pkgdir" install

  install -Dm644 debootstrap.8 "$pkgdir"/usr/share/man/man8/debootstrap.8
}