# Maintainer: Luke Shumaker <lukeshu@parabola.nu>

pkgname=dbscripts
pkgver=20180425
pkgdesc='Server-side programs for Parabola Pacman repositories'
url='https://git.parabola.nu/packages/dbscripts.git/'
license=('GPL')
backup=(
	etc/$pkgname/config
	etc/$pkgname/db-cleanup.conf
	etc/$pkgname/db-import-packages.conf
	etc/$pkgname/db-import-community.conf
	etc/$pkgname/db-import-archlinux32.conf
	etc/$pkgname/db-import-archlinuxarm.conf
)

pkgrel=1
arch=('any')
depends=(librelib 'xbs>=20180326' rsync)
checkdepends=(libretools)
source=("https://repo.parabola.nu/other/$pkgname/$pkgname-$pkgver.tar.gz")
sha256sums=('334b312bc6ce44d68f6f26f770e7fd61a7da6462d43c3cbfc607f0e3cddc71a3')

_gitver='commit=3867f0435b2d98278657fc47558ff44c9f554247'
mksource=("$pkgname-$pkgver::git://git.parabola.nu/packages/dbscripts.git/#$_gitver")
mkmd5sums=('SKIP')

package() {
	mkdir -p "$pkgdir"/opt
	cp -a "$srcdir/$pkgname-$pkgver" "$pkgdir/opt/$pkgname"

	mkdir -p "$pkgdir"/usr/bin
	find "$pkgdir/opt/$pkgname" -maxdepth 1 -type f -executable -exec ln -sr {} "$pkgdir"/usr/bin \;

	mkdir -p "$pkgdir"/etc/$pkgname
	local file
	for file in "${backup[@]}"; do
		mv -T "$pkgdir/opt/$pkgname/${file##*/}" "$pkgdir/$file"
		ln -sr "$pkgdir/$file" "$pkgdir/opt/$pkgname"
	done

	mkdir -p "$pkgdir"/usr/share/doc/$pkgname
	ln -sr "$pkgdir"/opt/$pkgname/README.md "$pkgdir"/usr/share/doc/$pkgname
}