# Maintainer: Luke Shumaker <lukeshu@parabola.nu>

pkgname=dbscripts
pkgver=20180612
pkgdesc='Server-side programs for Parabola Pacman repositories'
url='https://git.parabola.nu/packages/dbscripts.git/'
license=('GPL')
backup=(
	etc/$pkgname/config
	etc/$pkgname/config.local
	etc/$pkgname/config.local.archlinux32
	etc/$pkgname/config.local.archlinuxarm
	etc/$pkgname/config.local.community
	etc/$pkgname/config.local.packages
	etc/$pkgname/config.local.parabola
	etc/$pkgname/db-cleanup.conf
	etc/$pkgname/db-import-packages.conf
	etc/$pkgname/db-import-community.conf
	etc/$pkgname/db-import-archlinux32.conf
	etc/$pkgname/db-import-archlinuxarm.conf
)

pkgrel=1
arch=('any')
depends=('librelib>=20180428' 'xbs>=20180326' rsync)
checkdepends=(libretools)
source=("https://repo.parabola.nu/other/$pkgname/$pkgname-$pkgver.tar.gz"{,.sig})
sha256sums=('e2b48d394cdbc09814439381f571ae768018f9b2f20547497b655adac88dd4c5'
            'SKIP')
validpgpkeys=('99195DD3BB6FE10A2F36ED8445698744D4FFBFC9') # Luke Shumaker

_gitver='commit=77b61a24ab1e71f65215c968ba7b118b6ac5e10a'
mksource=("$pkgname-$pkgver::git://git.parabola.nu/packages/dbscripts.git/#$_gitver")
mkmd5sums=('SKIP')

package() {
	mkdir -p "$pkgdir"/opt
	cp -a "$srcdir/$pkgname-$pkgver" "$pkgdir/opt/$pkgname"

	mkdir -p "$pkgdir"/usr/bin
	find "$pkgdir/opt/$pkgname" -maxdepth 1 -type f -executable -not -name 'config-*' -exec ln -sr {} "$pkgdir"/usr/bin \;

	mkdir -p "$pkgdir"/etc/$pkgname
	local file
	for file in "${backup[@]}"; do
		mv -T "$pkgdir/opt/$pkgname/${file##*/}" "$pkgdir/$file"
		ln -sr "$pkgdir/$file" "$pkgdir/opt/$pkgname"
	done

	mkdir -p "$pkgdir"/usr/lib/systemd/system
	mv -t "$pkgdir"/usr/lib/systemd/system "$pkgdir/opt/$pkgname/systemd"/*.{service,timer}
	local src dst
	for src in "$pkgdir/opt/$pkgname/systemd"/*.d_*.conf; do
		dst="${src##*/}"
		dst="$pkgdir/usr/lib/systemd/system/${dst/.d_/.d/}"
		mkdir -p "${dst%/*}"
		mv -T "$src" "$dst"
	done
	rmdir "$pkgdir/opt/$pkgname/systemd"

	mkdir -p "$pkgdir"/usr/share/doc/$pkgname
	ln -sr "$pkgdir"/opt/$pkgname/README.md "$pkgdir"/usr/share/doc/$pkgname
}