# $Id: PKGBUILD 174970 2013-01-09 16:29:59Z andyrtr $
# Maintainer: Andreas Radke <andyrtr@archlinux.org>

pkgname=cups-filters-libre
_pkgname=cups-filters
pkgver=1.0.29
pkgrel=3
pkgdesc="OpenPrinting CUPS Filters"
arch=('i686' 'x86_64')
url="http://www.linuxfoundation.org/collaborate/workgroups/openprinting"
license=('GPL')
depends=('lcms2' 'poppler>=0.22.0' 'qpdf>=4.0.0')
makedepends=('ghostscript' 'ttf-dejavu') # ttf-dejavu for make check
optdepends=('ghostscript: for non-PostScript printers to print with CUPS to convert PostScript to raster images'
	    'foomatic-db: drivers use Ghostscript to convert PostScript to a printable form directly'
	    'foomatic-db-engine: drivers use Ghostscript to convert PostScript to a printable form directly')
backup=(etc/fonts/conf.d/99pdftoopvp.conf)
options=(!libtool)
source=(http://www.openprinting.org/download/cups-filters/$_pkgname-$pkgver.tar.gz
        cups-browsed.service
        poppler_buildfix.diff)
md5sums=('0640a02a3fb88d3dbdb224e3becd400d'
         '4c9f97eae201798000483c4e7109e690'
         'bd97d1d9dbd4feec3a0330fd9fb7a03c')
replaces=("${_pkgname}")
conflicts=("${_pkgname}")
provides=("${_pkgname}=${pkgver}")

build() {
  cd "$srcdir/$_pkgname-$pkgver"
  
  # fix build with poppler 0.22
  patch -Np0 -i ${srcdir}/poppler_buildfix.diff
  
  ./configure --prefix=/usr  \
    --sysconfdir=/etc \
    --with-rcdir=no \
    --enable-avahi \
    --with-test-font-path=/usr/share/fonts/TTF/DejaVuSans.ttf
  make
}

check() {
  cd "$srcdir/$_pkgname-$pkgver"
  make -j1 -k check
}

package() {
  cd "$srcdir/$_pkgname-$pkgver"
  make DESTDIR="$pkgdir/" install
  # drop static lib
  rm -f ${pkgdir}/usr/lib/*.a
  
  # add missing systemd support
  install -Dm644 ${srcdir}/cups-browsed.service ${pkgdir}/usr/lib/systemd/system/cups-browsed.service
}