# $Id: PKGBUILD 200098 2016-12-18 10:27:54Z arojas $
# Maintainer (Arch): Sergej Pupykin <pupykin.s+arch@gmail.com>
# Contributor (Arch): Maxim Vuets <maxim.vuets@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=cuneiform
pkgver=1.1.0
_dpkgver=1.1
pkgrel=15.parabola1
pkgdesc="GNU/Linux port of an OCR system developed in Russia. Supports more than 20 languages, without nonfree data files"
arch=('i686' 'x86_64')
url="https://launchpad.net/cuneiform-linux"
license=('BSD')
depends=('imagemagick')
makedepends=('cmake' 'gcc5')
mksource=(http://launchpad.net/cuneiform-linux/${_dpkgver}/${_dpkgver}/+download/cuneiform-linux-${pkgver}.tar.bz2)
source=("https://repo.parabola.nu/other/${pkgname}-libre/${pkgname}-libre-${pkgver}.tar.bz2"
        'libre.patch')
mksha256sums=('577e0d054de72086c33b4e8ae15033657776509b9a7af6eb272888eefcbdbbad')
sha256sums=('714b740d79c4799ec1bd340e3721d17f6d0e09ae54cd5667a01eddc8c4b758b4'
            '9db29dcd11faf92ed68d4af35c659b6f5e96b0864c15342be8e014817af8be2d')

mksource() {
  mv "${srcdir}/${pkgname}-linux-${pkgver}" "${srcdir}/${pkgname}-${pkgver}"
  cd "${srcdir}/${pkgname}-${pkgver}"
  rm -rv datafiles
}

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  patch -p1 -i ../libre.patch
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  sed -i 's#lib64#lib#' install_files.cmake
  mkdir -p builddir
  cd builddir

  LMAGICK=`ls -1 /usr/lib/libMagick++*.so.?`

  cmake \
	-DCMAKE_BUILD_TYPE=release \
	-DCMAKE_INSTALL_PREFIX=/usr \
	-DCMAKE_CXX_COMPILER=g++-5 \
	-DCMAKE_C_COMPILER=gcc-5 \
	-DImageMagick_Magick++_LIBRARY=$LMAGICK \
	-DImageMagick_Magick++_INCLUDE_DIR=/usr/include/ImageMagick-6 \
	..
  make
}

check() {
  ldd "${srcdir}/${pkgname}-${pkgver}/builddir/cuneiform" | grep Magick >/dev/null
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"/builddir
  make DESTDIR="${pkgdir}" install

  install -Dm644 "${srcdir}/${pkgname}-${pkgver}/cuneiform_src/Kern/license.txt" \
    "${pkgdir}/usr/share/licenses/cuneiform/license.txt"
}