# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor (Arch): Doug Newgard <scimmia at archlinux dot info>
# Contributor (Arch): Andrey Mivrenik <gim at fastmail dot fm>
# Contributor (Arch): Glen Oakley <goakley123@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>

pkgname=cool-retro-term
pkgver=1.0.0
pkgrel=4.parabola1
pkgdesc='A good looking terminal emulator which mimics the old cathode display, without nonfree fonts'
arch=('i686' 'x86_64')
url='https://github.com/Swordfish90/cool-retro-term'
license=('GPL3')
depends=('qmltermwidget' 'qt5-quickcontrols' 'qt5-graphicaleffects' 'hicolor-icon-theme')
mksource=("https://github.com/Swordfish90/cool-retro-term/archive/v$pkgver.tar.gz")
source=("https://repo.parabola.nu/other/cool-retro-term-libre/cool-retro-term-libre-$pkgver.tar.gz")
mksha256sums=('db799084680545b6961e1b3d1bb7ff0cb8105e82279fe734c2c07c32525350d9')
sha256sums=('a59fb6ead92d02873dc0d423c5a60c43bcc48a732b7616f8aef76f1f5f2bd357')

mksource() {
  cd "$srcdir/$pkgname-$pkgver"

  rm -rv app/qml/fonts/{1977-{apple2,commodore-pet},1982-commodore64,modern-envy-code-r}
}

prepare() {
  cd "$srcdir/$pkgname-$pkgver"

  sed -i '/qmltermwidget/d' cool-retro-term.pro
  sed -i '/1977-apple2/d
          /1977-commodore-pet/d
          /1982-commodore64/d
          /modern-envy-code-r/d
         ' app/qml/resources.qrc
}

build() {
  cd "$srcdir/$pkgname-$pkgver"

  qmake
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"

  make INSTALL_ROOT="$pkgdir" install
}