# Maintainer (Arch): Jelle van der Waa <jelle@vdwaa.nl>
# Maintainer (Arch): Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor (Arch): Giovanni Scafora <giovanni@archlinux.org>
# Contributor (Arch): Petrov Roman <nwhisper@gmail.com>
# Contributor (Arch): Andrea Fagiani <andfagiani _at_ gmail dot com>
# Contributor (Arch): Larry Hajali <larryhaja@gmail.com>
# Contributor (Arch): Eli Schwartz <eschwartz93@gmail.com>
# Contributor: André Silva <emulatorman@riseup.net>
# Contributor: Márcio Silva <coadde@riseup.net>

pkgname=calibre
pkgver=2.85.1
pkgrel=2.parabola2
pkgdesc="Ebook management application, without nonfree decompression engine for RAR archives"
arch=('x86_64' 'i686' 'armv7h')
url="https://calibre-ebook.com/"
license=('GPL3')
depends=('python2-six' 'python2-dateutil' 'python2-cssutils' 'python2-cherrypy'
         'python2-mechanize' 'podofo' 'libwmf'
         'chmlib' 'python2-lxml' 'libusbx'
         'python2-pillow' 'shared-mime-info' 'python2-dnspython'
         'python2-pyqt5' 'python2-psutil' 'icu' 'libmtp' 'python2-dbus'
         'python2-netifaces' 'python2-cssselect' 'python2-apsw' 'qt5-webkit'
         'qt5-svg' 'python2-chardet' 'python2-pygments' 'mtdev'
         'desktop-file-utils' 'gtk-update-icon-cache' 'optipng' 'udisks2')
makedepends=('qt5-x11extras' 'xdg-utils')
optdepends=('ipython2: to use calibre-debug'
            'poppler: required for converting pdf to html')
replaces=($pkgname-libre)
conflicts=($pkgname-libre)
source=("http://download.$pkgname-ebook.com/${pkgver}/$pkgname-${pkgver}.tar.xz"
        "https://calibre-ebook.com/signatures/${pkgname}-${pkgver}.tar.xz.sig"
        'libre.patch'
        '0001-Remove-new_version_notification.patch'
        '0001-Remove-code-that-contacts-calibre-servers-to-check-u.patch')
sha512sums=('ce29924213fa7461bbf2fc62f26bd53e4eafdf3b0dd58e241071592be4ee038cdb3ac6ac2982229dd0e52595a93aca7d921640ea55796950d1f3ac3c2742af4f'
            'SKIP'
            '4fc44d06ed9a1107a2eb17e9ab9b0b502dc4210d0776350d285d9b8a52e35b87f15457bcc8fe57336289c6f5700be7ef1c070b14925a8f761b9b2b61c0fd0e5e'
            'e6c3b1ddbd72c4e1cd1b883283102c7e185e2badded24b9d1920364b4ec96ad60fd68d558bfce69e90739568de01aae81ae5ed349f1700697ba153f6d251e2ba'
            '29b57398f8243bfa452983413f34b48d69da1577286455ed1356b2c1d12043af70ad389d02a8d64ad848ba4883243b66c7aab7805f3a82deac611bb41e0556f7')
validpgpkeys=('3CE1780F78DD88DF45194FD706BC317B515ACE7C')

prepare(){
  cd "${pkgname}-${pkgver}"

  # Remove nonfree unRAR utility files from the source
  rm -rv src/unrar
  
  # Remove nonfree rar/cbr support and references
  rm -v src/calibre/{ebooks/metadata/rar.py,utils/unrar.{cpp,py}}
  rm -v resources/images/mimetypes/{cbr,rar}.png
  rm -v imgsrc/mimetypes/rar.svg
  patch -Np1 -i "${srcdir}/libre.patch"
  patch -Np1 -i "${srcdir}/0001-Remove-new_version_notification.patch"
  patch -Np1 -i "${srcdir}/0001-Remove-code-that-contacts-calibre-servers-to-check-u.patch"

  # Remove unneeded files and libs
  # FIXME: remove html5lib too, but the latest html5lib breaks calibre. And calibre
  # really needs to get the latest changes into html5lib, cause forking is bad m'okay.
  rm -rf resources/${pkgname}-portable.* \
         src/cherrypy \
         src/chardet

  # Desktop integration (e.g. enforce arch defaults)
  sed -e "/self.create_uninstaller()/,/os.rmdir(config_dir)/d" \
      -e "/cc(\['xdg-desktop-menu', 'forceupdate'\])/d" \
      -e "/cc(\['xdg-mime', 'install', MIME\])/d" \
      -e "s/'ctc-posml'/'text' not in mt and 'pdf' not in mt and 'xhtml'/" \
      -e "s/^Name=calibre/Name=Calibre/g" \
      -i  src/calibre/linux.py
}

build() {
  cd "${pkgname}-${pkgver}"

  LANG='en_US.UTF-8' python2 setup.py build
  LANG='en_US.UTF-8' python2 setup.py gui
}

package() {
  cd "${pkgname}-${pkgver}"

  install -d "${pkgdir}/usr/share/zsh/site-functions" \
             "${pkgdir}"/usr/share/{applications,desktop-directories,icons/hicolor}

  install -Dm644 resources/calibre-mimetypes.xml \
    "${pkgdir}/usr/share/mime/packages/calibre-mimetypes.xml"

  XDG_DATA_DIRS="${pkgdir}/usr/share" LANG='en_US.UTF-8' \
    python2 setup.py install --staging-root="${pkgdir}/usr" --prefix=/usr

  # Compiling bytecode FS#33392
  python2 -m compileall "${pkgdir}/usr/lib/calibre/"
  python2 -O -m compileall "${pkgdir}/usr/lib/calibre/"
}