# Maintainer (Arch): Jelle van der Waa <jelle@vdwaa.nl>
# Maintainer (Arch): Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor (Arch): Giovanni Scafora <giovanni@archlinux.org>
# Contributor (Arch): Petrov Roman <nwhisper@gmail.com>
# Contributor (Arch): Andrea Fagiani <andfagiani _at_ gmail dot com>
# Contributor (Arch): Larry Hajali <larryhaja@gmail.com>
# Contributor (Arch): Eli Schwartz <eschwartz93@gmail.com>
# Contributor: David P.<megver83@parabola.nu>
# Maintainer: Jesús E.<heckyel@parabola.nu>

pkgname=calibre
_commit="d695ad008a67de9753d79b0144125031713fa851"
pkgver=3.9.0
pkgrel=1.parabola1
_mathjax_ver=2.6.1
pkgdesc="Ebook management application, without nonfree decompression engine for RAR archives"
arch=('x86_64' 'i686' 'armv7h')
url="https://calibre-ebook.com/"
license=('GPL3')
depends=('chmlib' 'icu' 'libmtp' 'libusbx' 'libwmf' 'mtdev'
         'optipng' 'podofo' 'python2-apsw' 'python2-cssselect'
         'python2-cssutils' 'python2-dateutil' 'python2-dbus' 'python2-dnspython'
         'python2-dukpy' 'python2-html5-parser' 'python2-mechanize' 'python2-msgpack'
         'python2-netifaces' 'python2-pillow' 'python2-psutil' 'python2-pygments'
         'python2-pyqt5' 'python2-regex' 'qt5-svg' 'qt5-webkit')
makedepends=('qt5-x11extras' 'xdg-utils' 'rapydscript-ng' 'python2-sphinx')
optdepends=('ipython2: to use calibre-debug -g'
            'poppler: required for converting pdf to html')
replaces=($pkgname-libre)
conflicts=($pkgname-libre)
source=("$pkgname-$pkgver.tar.gz::https://gitlab.com/Megver83/calibre/repository/archive.tar.gz?ref=$pkgver"
        "$pkgname-$pkgver.tar.gz.sig::https://gitlab.com/Megver83/calibre/raw/signatures/$pkgname-$pkgver-${_commit}.tar.gz.sig"
        "$pkgname-translations.zip::https://github.com/kovidgoyal/${pkgname}-translations/archive/master.zip"
        "MathJax-${_mathjax_ver}.tar.gz::https://github.com/kovidgoyal/MathJax/archive/${_mathjax_ver}.tar.gz")
sha512sums=('90cfa8e9d76e2c8d6ff2338d37335dd41cdf9a2d2290bee1bb60cb97106f5a7783d0bbbde1a0bbc55ecbf8b8c302dc79c24dd800a3976426ce59a52019bb6aa7'
            'SKIP'
            '787916c15ee3edd73b435ea8dbb6e7274fd105231278dd605866768a6113f47a2e5b019eb2833d4e376457c1c29a68d34a64b2a45d1af3174e61ed513458b1cc'
            '23e1f08cc8df16f27eb9316e3e2975bdf716d3205907dc55fa907282d70de4d7637e930a42f1bc002622d5831093efdc68c22be6f0512d4dedc7c0d8cda3230c')
validpgpkeys=('6DB9C4B4F0D8C0DC432CF6E4227CA7C556B2BA78' # David P.
              '916FFBC76D2E641BA416BA53364F4E1483446AC5' # Jesús E.
)

prepare() {
  # move directories
  mv "$pkgname-$pkgver-${_commit}" "$pkgname-$pkgver"

  cd "$pkgname-$pkgver"

  # Link translations to build dir
  ln -sfT ../calibre-translations-master translations

  # Desktop integration (e.g. enforce arch defaults)
  # Use uppercase naming scheme, don't create uninstaller.
  # xdg *cannot* be kludged into installing mime files properly.
  sed -e "/self.create_uninstaller()/,/os.rmdir(config_dir)/d" \
      -e "/cc(\['xdg-desktop-menu', 'forceupdate'\])/d" \
      -e "/cc(\['xdg-mime', 'install', MIME\])/d" \
      -e "s/'ctc-posml'/'text' not in mt and 'pdf' not in mt and 'xhtml'/" \
      -e "s/^Name=calibre/Name=Calibre/g" \
      -i  src/calibre/linux.py
}

build() {
  cd "$pkgname-$pkgver"

  # Don't use the bootstrapper, since it tries to checkout/pull the
  # translations repo and generally touch the internet. Instead call each
  # *needed* subcommmand.
  # LANG='en_US.UTF-8' python2 setup.py bootstrap

  LANG='en_US.UTF-8' python2 setup.py build
  LANG='en_US.UTF-8' python2 setup.py iso639
  LANG='en_US.UTF-8' python2 setup.py iso3166
  LANG='en_US.UTF-8' python2 setup.py translations
  LANG='en_US.UTF-8' python2 setup.py gui
  LANG='en_US.UTF-8' python2 setup.py resources
  LANG='en_US.UTF-8' python2 setup.py man_pages
  LANG='en_US.UTF-8' python2 setup.py recent_uas || true
  LANG='en_US.UTF-8' python2 setup.py mathjax --path-to-mathjax="${srcdir}/MathJax-${_mathjax_ver}"
}

package() {
  cd "$pkgname-$pkgver"

  # If these directories don't exist, zsh completion, icons, and desktop files won't install.
  install -d "${pkgdir}/usr/share/zsh/site-functions" \
    "${pkgdir}"/usr/share/{applications,desktop-directories,icons/hicolor}

  XDG_DATA_DIRS="${pkgdir}/usr/share" LANG='en_US.UTF-8' \
    python2 setup.py install --staging-root="${pkgdir}/usr" --prefix=/usr

  cp -a man-pages/ "${pkgdir}/usr/share/man"

  install -Dm644 resources/calibre-mimetypes.xml \
    "${pkgdir}/usr/share/mime/packages/calibre-mimetypes.xml"

  # Compiling bytecode FS#33392
  python2 -m compileall "${pkgdir}/usr/lib/calibre/"
  python2 -O -m compileall "${pkgdir}/usr/lib/calibre/"
}