# Maintainer: Andreas Grapentin <andreas@grapentin.org>
# Maintainer (Arch): Jelle van der Waa <jelle@vdwaa.nl>
# Maintainer (Arch): Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor (Arch): Giovanni Scafora <giovanni@archlinux.org>
# Contributor (Arch): Petrov Roman <nwhisper@gmail.com>
# Contributor (Arch): Andrea Fagiani <andfagiani _at_ gmail dot com>
# Contributor (Arch): Larry Hajali <larryhaja@gmail.com>
# Contributor (Arch): Eli Schwartz <eschwartz93@gmail.com>
# Contributor: David P.<megver83@parabola.nu>
# Contributor: Jesús E.<heckyel@parabola.nu>
# Contributor: Isaac David <isacdaavid@at@isacdaavid@dot@info>

pkgname=calibre
pkgver=3.15.0
pkgrel=1.parabola1
arch=(x86_64 i686 armv7h)

pkgdesc="Ebook management application, without nonfree decompression engine for RAR archives"
url="https://calibre-ebook.com/"
license=(GPL3)

depends=(python2-six python2-dateutil python2-cssutils python2-dukpy
         python2-mechanize podofo libwmf
         chmlib python2-lxml libusbx python2-html5-parser
         python2-pillow shared-mime-info python2-dnspython python2-msgpack
         python2-pyqt5 python2-psutil libmtp python2-dbus
         python2-netifaces python2-cssselect python2-apsw qt5-webkit
         qt5-svg python2-regex python2-pygments mtdev
         desktop-file-utils gtk-update-icon-cache optipng udisks2)
depends_x86_64=("icu>=60" "icu<61")
depends_i686=("icu>=60" "icu<61")
depends_armv7h=("icu>=60" "icu<61")
makedepends=(qt5-x11extras xdg-utils)
optdepends=('ipython2: to use calibre-debug'
            'poppler: required for converting pdf to html')
replaces=($pkgname-libre)
conflicts=($pkgname-libre)

# for updated libre.patch commit id see: https://gitlab.com/libreforks/calibre/tags
_commit='11f261b5db0b2f0d23e5067368ce73d6'
source=("https://download.calibre-ebook.com/$pkgver/calibre-$pkgver.tar.xz"
        "https://calibre-ebook.com/signatures/$pkgname-$pkgver.tar.xz.sig"
        "https://gitlab.com/libreforks/calibre/uploads/$_commit/libre.patch")
sha256sums=('8746f52315561d606fd7120fec8284c2e4433f6ead14639c40b4b5f1522273ff'
            'SKIP'
            'b218de451ac29081071b6ba965c543bfeb6fb9c5a1bdcedfa02b27811c986dd6')
validpgpkeys=('3CE1780F78DD88DF45194FD706BC317B515ACE7C')

prepare() {
  cd "$pkgname-$pkgver"

  # Remove unneeded files
  rm -rf resources/$pkgname-portable.*
  rm -rf resources/images/mimetypes/{cbr,rar}.png

  # fix freedom issues
  patch -fNp1 -i "$srcdir/libre.patch" || true # unfortunately, patch chokes on files we deleted before...

  # Desktop integration (e.g. enforce arch defaults)
  sed -e "/self.create_uninstaller()/,/os.rmdir(config_dir)/d" \
      -e "/cc(\['xdg-desktop-menu', 'forceupdate'\])/d" \
      -e "/cc(\['xdg-mime', 'install', MIME\])/d" \
      -e "s/'ctc-posml'/'text' not in mt and 'pdf' not in mt and 'xhtml'/" \
      -e "s/^Name=calibre/Name=Calibre/g" \
      -i  src/calibre/linux.py
}

build() {
  cd "$pkgname-$pkgver"

  LANG='en_US.UTF-8' python2 setup.py build
  LANG='en_US.UTF-8' python2 setup.py gui
}

package() {
  cd "$pkgname-$pkgver"

  install -d "$pkgdir/usr/share/zsh/site-functions" \
             "$pkgdir"/usr/share/{applications,desktop-directories,icons/hicolor}

  install -Dm644 resources/calibre-mimetypes.xml \
    "$pkgdir/usr/share/mime/packages/calibre-mimetypes.xml"

  XDG_DATA_DIRS="$pkgdir/usr/share" LANG='en_US.UTF-8' \
    python2 setup.py install --staging-root="$pkgdir/usr" --prefix=/usr

  cp -a man-pages/ "$pkgdir/usr/share/man"

  # Compiling bytecode FS#33392
  python2 -m compileall "$pkgdir/usr/lib/calibre/"
  python2 -O -m compileall "$pkgdir/usr/lib/calibre/"
}