# Maintainer (Arch): Jelle van der Waa <jelle@vdwaa.nl>
# Maintainer (Arch): Daniel Wallace <danielwallace at gtmanfred dot com>
# Contributor (Arch): Giovanni Scafora <giovanni@archlinux.org>
# Contributor (Arch): Petrov Roman <nwhisper@gmail.com>
# Contributor (Arch): Andrea Fagiani <andfagiani _at_ gmail dot com>
# Contributor (Arch): Larry Hajali <larryhaja@gmail.com>
# Contributor (Arch): Eli Schwartz <eschwartz93@gmail.com>
# Contributor: André Silva <emulatorman@riseup.net>
# Contributor: Márcio Silva <coadde@riseup.net>

pkgname=calibre
pkgver=3.0.0
pkgrel=1.parabola1
pkgdesc="Ebook management application, without nonfree decompression engine for RAR archives"
arch=('x86_64' 'i686' 'armv7h')
url="https://calibre-ebook.com/"
license=('GPL3')
depends=('python2-six' 'python2-dateutil' 'python2-cssutils' 'python2-cherrypy'
         'python2-mechanize' 'podofo' 'libwmf'
         'chmlib' 'python2-lxml' 'libusbx'
         'python2-pillow' 'shared-mime-info' 'python2-dnspython'
         'python2-pyqt5' 'python2-psutil' 'icu' 'libmtp' 'python2-dbus'
         'python2-netifaces' 'python2-cssselect' 'python2-apsw' 'qt5-webkit'
         'qt5-svg' 'python2-chardet' 'python2-regex' 'python2-pygments' 'mtdev'
         'desktop-file-utils' 'gtk-update-icon-cache' 'optipng' 'udisks2')
makedepends=('qt5-x11extras' 'xdg-utils')
optdepends=('ipython2: to use calibre-debug'
            'poppler: required for converting pdf to html')
replaces=($pkgname-libre)
conflicts=($pkgname-libre)
source=("http://download.$pkgname-ebook.com/${pkgver}/$pkgname-${pkgver}.tar.xz"
        "https://calibre-ebook.com/signatures/${pkgname}-${pkgver}.tar.xz.sig"
        'libre.patch'
        '0001-Remove-code-that-contacts-calibre-servers-to-check-u.patch'
        '0002-Remove-new_version_notification.patch'
        '0003-Disable-plugin-dialog.patch'
        '0004-Disable-update-check-by-default.patch'
        '0005-Use-packaged-instead-of-bundled-feedparser-Python-module.patch')
sha512sums=('3845e05c411334c0f14d116088d5b14d618a623596386ab0eaa2d888f561ca38979abef35d2056e0052fab32dc1e8c4433f6bc656c8bb7917bd98086c070e969'
            'SKIP'
            'cf3d97e7dfe3001262de5c47e415b0b617a0b110f0aeec04a10bcdcaf810203b7bf67a9c8438928d5319229dec9a5b6a88f914a79c02a314eb3f9435b7d3892c'
            'd908af0a46d06626e25568dbf3d07e738171822563ade815987035b250fdf49c979091e4a25d42919a92689d1a6e68fc6d90208a2cb9d16f23fe42496e6ce07c'
            '02047687608e917fc877248c92be140e8c01c7ce5ac8230b5f9094229da77507b5bc40149e9392145ee702e45974606337bf8b33f3162469065d1b11f4f19059'
            '1e3baa6749bd566b2025eb703df2dfde35347d505341e2c74e5326e8b6eff18cd28b67a4eef651ad5a5ed5f4abaacc4e6b12970b11c267bb63b3334e10268442'
            '3dce2ae13f666e31ffdc52a4f6dcfc47d6d872d08800c7552b411889576fa7d0ffb43047f98e746a8a7b265b9dceb7ff55b62f5a935de2fd675ccad87fcdfeec'
            '802e864a670fdb7a7bd2e9ebf3e3ca4e8566a724cbf931de577ed103f3783ff5b44d9985564692c59153350558a0f8fdaac8ddb3229d2ffb0a66688bbcc5f9fd')
validpgpkeys=('3CE1780F78DD88DF45194FD706BC317B515ACE7C') # Kovid Goyal

prepare(){
  cd "${pkgname}-${pkgver}"

  # Remove nonfree unRAR utility files from the source
  rm -rv src/unrar
  
  # Remove nonfree rar/cbr support and references
  rm -v src/calibre/{ebooks/metadata/rar.py,utils/unrar.{cpp,py}}
  rm -v resources/images/mimetypes/{cbr,rar}.png
  rm -v imgsrc/mimetypes/rar.svg
  patch -Np1 -i "${srcdir}/libre.patch"
  patch -Np1 -i "${srcdir}/0001-Remove-code-that-contacts-calibre-servers-to-check-u.patch"
  patch -Np1 -i "${srcdir}/0002-Remove-new_version_notification.patch"
  patch -Np1 -i "${srcdir}/0003-Disable-plugin-dialog.patch"
  patch -Np1 -i "${srcdir}/0004-Disable-update-check-by-default.patch"
  patch -Np1 -i "${srcdir}/0005-Use-packaged-instead-of-bundled-feedparser-Python-module.patch"

  # Remove unneeded files and libs
  # FIXME: remove html5lib too, but the latest html5lib breaks calibre. And calibre
  # really needs to get the latest changes into html5lib, cause forking is bad m'okay.
  rm -rf resources/${pkgname}-portable.* \
         src/cherrypy \
         src/chardet

  # Desktop integration (e.g. enforce arch defaults)
  sed -e "/self.create_uninstaller()/,/os.rmdir(config_dir)/d" \
      -e "/cc(\['xdg-desktop-menu', 'forceupdate'\])/d" \
      -e "/cc(\['xdg-mime', 'install', MIME\])/d" \
      -e "s/'ctc-posml'/'text' not in mt and 'pdf' not in mt and 'xhtml'/" \
      -e "s/^Name=calibre/Name=Calibre/g" \
      -i  src/calibre/linux.py
}

build() {
  cd "${pkgname}-${pkgver}"

  LANG='en_US.UTF-8' python2 setup.py build
  LANG='en_US.UTF-8' python2 setup.py gui
}

package() {
  cd "${pkgname}-${pkgver}"

  install -d "${pkgdir}/usr/share/zsh/site-functions" \
             "${pkgdir}"/usr/share/{applications,desktop-directories,icons/hicolor}

  install -Dm644 resources/calibre-mimetypes.xml \
    "${pkgdir}/usr/share/mime/packages/calibre-mimetypes.xml"

  XDG_DATA_DIRS="${pkgdir}/usr/share" LANG='en_US.UTF-8' \
    python2 setup.py install --staging-root="${pkgdir}/usr" --prefix=/usr

  # Compiling bytecode FS#33392
  python2 -m compileall "${pkgdir}/usr/lib/calibre/"
  python2 -O -m compileall "${pkgdir}/usr/lib/calibre/"
}