# $Id: PKGBUILD 196818 2013-10-20 08:27:26Z andyrtr $
# Maintainer (Arch): AndyRTR <andyrtr@archlinux.org>
# Contributor (Arch): tobias <tobias@archlinux.org>
# Contributor (Arch): Low Kian Seong <fastmail_low@speedymail.org>
# Maintainer: Márcio Silva <marcio@parabola.nu>

pkgname=bogofilter
_pkgname=$pkgname-libre
pkgver=1.2.4
pkgrel=1.parabola1
pkgdesc="A fast Bayesian spam filtering tool, without noncommercial files"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL3')
url="http://$pkgname.sourceforge.net"
depends=('db' 'perl' 'gsl')
backup=("etc/$pkgname/$pkgname.cf")
mksource=(http://sourceforge.net/projects/${pkgname}/files/${pkgname}-current/${pkgname}-${pkgver}/${pkgname}-${pkgver}.tar.bz2)
source=(https://repo.parabola.nu/other/${_pkgname}/${_pkgname}-${pkgver}.tar.bz2)
mkmd5sums=('d0a5eebb3274b23ceabe766a6443a1c5')
md5sums=('cce573e059d39a68cf78097dbfaa5b2d')
replaces=("${_pkgname}")
conflicts=("${_pkgname}")

mksource() {
  cd ${pkgname}-${pkgver}

  # Remove noncommercial files.
  rm doc/$pkgname-SA-{2005-0{1,2},2010-01}
}

build() {
  cd ${pkgname}-${pkgver}

  ./configure --prefix=/usr \
              --sysconfdir=/etc/$pkgname  \
              --localstatedir=/var \
              --enable-transactions
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install

  mv "${pkgdir}/etc/$pkgname/$pkgname.cf.example" "${pkgdir}/etc/$pkgname/$pkgname.cf"

  install -dm755 "${pkgdir}/usr/share/${pkgname}/contrib"
  install -m644 contrib/* "${pkgdir}/usr/share/${pkgname}/contrib/"
}