# $Id: PKGBUILD 146459 2012-01-11 15:21:47Z stephane $
# Maintainer: tobias <tobias@archlinux.org>
# Contributor: Low Kian Seong <fastmail_low@speedymail.org>

_pkgname=bogofilter
pkgname=bogofilter-libre
pkgver=1.2.2
pkgrel=5
pkgdesc="A fast Bayesian spam filtering tool"
arch=('i686' 'x86_64')
license=('GPL3')
url="http://bogofilter.sourceforge.net"
depends=('db' 'perl' 'gsl')
backup=('etc/bogofilter/bogofilter.cf')
source=(http://repo.parabolagnulinux.org/other/${pkgname}-${pkgver}.tar.xz)
md5sums=('af9c7857c66b1884c820f54f23082701')
provides=("${_pkgname}=${pkgver}")
replaces=("${_pkgname}")
conflicts=("${_pkgname}")

mksource() {
    [ -f ${_pkgname}-${pkgver}.tar.bz2 ] || wget http://sourceforge.net/projects/${_pkgname}/files/${_pkgname}-current/${_pkgname}-${pkgver}/${_pkgname}-${pkgver}.tar.bz2
    tar xf ${_pkgname}-${pkgver}.tar.bz2
    # Remove noncommercial files.
    rm ${_pkgname}-${pkgver}/doc/bogofilter-SA-{2005-0{1,2},2010-01}
    tar cJf ${pkgname}-${pkgver}.tar.xz ${_pkgname}-${pkgver}
}

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  ./configure --prefix=/usr \
              --sysconfdir=/etc/bogofilter  \
              --localstatedir=/var \
              --enable-transactions
  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install

  mv "${pkgdir}/etc/bogofilter/bogofilter.cf.example" "${pkgdir}/etc/bogofilter/bogofilter.cf"

  install -dm755 "${pkgdir}/usr/share/${_pkgname}/contrib"
  install -m644 contrib/* "${pkgdir}/usr/share/${_pkgname}/contrib/"
}