# $Id: PKGBUILD 196818 2013-10-20 08:27:26Z andyrtr $
# Maintainer (Arch): AndyRTR <andyrtr@archlinux.org>
# Contributor (Arch): tobias <tobias@archlinux.org>
# Contributor (Arch): Low Kian Seong <fastmail_low@speedymail.org>

_pkgname=bogofilter
pkgname=bogofilter-libre
pkgver=1.2.4
pkgrel=1
pkgdesc="A fast Bayesian spam filtering tool, without noncommercial files"
arch=('i686' 'x86_64')
license=('GPL3')
url="http://bogofilter.sourceforge.net"
depends=('db' 'perl' 'gsl')
backup=('etc/bogofilter/bogofilter.cf')
mksource=(http://sourceforge.net/projects/${_pkgname}/files/${_pkgname}-current/${_pkgname}-${pkgver}/${_pkgname}-${pkgver}.tar.bz2)
source=(https://repo.parabolagnulinux.org/other/${pkgname}/${pkgname}-${pkgver}.tar.bz2)
mkmd5sums=('d0a5eebb3274b23ceabe766a6443a1c5')
md5sums=('cce573e059d39a68cf78097dbfaa5b2d')
provides=("${_pkgname}=${pkgver}")
replaces=("${_pkgname}")
conflicts=("${_pkgname}")

mksource() {
  cd ${_pkgname}-${pkgver}

  # Remove noncommercial files.
  rm doc/bogofilter-SA-{2005-0{1,2},2010-01}
}

build() {
  cd ${_pkgname}-${pkgver}

  ./configure --prefix=/usr \
              --sysconfdir=/etc/bogofilter  \
              --localstatedir=/var \
              --enable-transactions
  make
}

package() {
  cd ${_pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install

  mv "${pkgdir}/etc/bogofilter/bogofilter.cf.example" "${pkgdir}/etc/bogofilter/bogofilter.cf"

  install -dm755 "${pkgdir}/usr/share/${_pkgname}/contrib"
  install -m644 contrib/* "${pkgdir}/usr/share/${_pkgname}/contrib/"
}