# Maintainer (Arch): Felix Yan <felixonmars@archlinux.org>
# Maintainer (Arch): Alexander F Rødseth <xyproto@archlinux.org>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor (Arch): SanskritFritz (gmail)
# Contributor (Arch): Tobias T. <OldShatterhand at gmx-topmail dot de>

pkgname=bibletime
pkgver=2.11.2
pkgrel=1
pkgrel+=.parabola1
pkgdesc='Bible study tool'
pkgdesc+=', with qt5-webkit-ng support'
arch=('x86_64')
arch+=('i686' 'armv7h')
url='http://www.bibletime.info/'
license=('GPL2')
depends=('sword' 'clucene' 'qt5-webkit' 'qt5-svg')
makedepends=('cmake' 'qt5-tools')
source=("$pkgname-$pkgver.tar.gz::https://github.com/bibletime/bibletime/archive/v$pkgver.tar.gz"
        'libre.patch')
sha512sums=('951c72dea1e281c0403284b36d680452ffb9dec180097faec49bc8536ad9a9e3cb543060b9972beae415e94467dbff6edcc253a0fda217cbb17a94fce40ff553'
            '6d64be9904729b9bdf7a0464af8ba9e230b400ee461aca6dc8c7060c8bdb870ad61494ae3cd6a2f32a7ef45605b88671350c83e6cf9406f334242c63139cdc0c')

prepare() {
  mkdir -p build

  cd bibletime-$pkgver
  patch -p1 -i "$srcdir/libre.patch"
}

build() {
  cd build

  cmake ../bibletime-$pkgver \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release
  make
}

package() {
  make -C build DESTDIR="$pkgdir" install
}

# vim:set ts=2 sw=2 et: