# $Id: PKGBUILD 117772 2014-08-22 15:36:25Z fyan $
# Maintainer (Arch): Timothy Redaelli <timothy.redaelli@gmail.com>
# Contributor (Arch): Andy Weidenbaum <archbaum@gmail.com>

pkgname=bfgminer
pkgver=4.7.0
pkgrel=1.parabola3
pkgdesc="Bitcoin miner featuring overclocking, monitoring, fan speed control and remote management. For FPGA/GPU/CPU Bitcoin mining, with opencl-mesa recommendation"
arch=('i686' 'x86_64' 'mips64el')
depends=('curl' 'jansson' 'libevent' 'libmicrohttpd' 'libusb' 'lm_sensors')
makedepends=('uthash' 'yasm')
optdepends=('opencl-mesa: OpenCL implementation for Mesa')
replaces=("${pkgname}-libre" "${pkgname}-parabola")
conflicts=("${pkgname}-libre" "${pkgname}-parabola")
url='http://bfgminer.org/'
license=('GPL3')
source=(http://luke.dashjr.org/programs/bitcoin/files/$pkgname/$pkgver/$pkgname-$pkgver.txz
        remove-dangerous-rpath.patch)
sha256sums=('044636103f2c399d8c0290e6642ef896cff43de3c025d99a1465e670337aeb0a'
            'd26d07ca23ae25798c4db37cfda1a6a76f22d06e73efab1ddf62b3e1a7eef04c')

prepare() {
  cd "$srcdir"/$pkgname-$pkgver

  patch -p0 < "${srcdir}"/remove-dangerous-rpath.patch
  NOSUBMODULES=1 ./autogen.sh
}

build() {
  cd "$srcdir"/$pkgname-$pkgver

  ./configure --prefix=/usr \
    --sbindir=/usr/bin \
    --enable-cpumining \
    --enable-bfsb \
    --enable-metabank \
    --enable-scrypt \
    --enable-opencl \
    --with-udevrulesdir=/usr/lib/udev/rules.d
  # --enable-knc (FS#33640)
  make
}

package() {
  cd "$srcdir"/$pkgname-$pkgver

  make DESTDIR="$pkgdir" install
}