# $Id: PKGBUILD 113111 2014-06-13 18:57:57Z eric $
# Maintainer (Arch): Timothy Redaelli <timothy.redaelli@gmail.com>
# Contributor (Arch): Andy Weidenbaum <archbaum@gmail.com>

_pkgname=bfgminer
pkgname=bfgminer-libre
pkgver=4.0.0
pkgrel=1
pkgdesc="Bitcoin miner featuring overclocking, monitoring, fan speed control and remote management. For FPGA/GPU/CPU Bitcoin mining, without nonfree OpenCL recommendation"
arch=('i686' 'x86_64' 'mips64el')
depends=('curl' 'jansson' 'libevent' 'libmicrohttpd' 'libusbx' 'lm_sensors')
makedepends=('uthash' 'yasm')
replaces=($_pkgname)
conflicts=($_pkgname)
provides=($_pkgname=$pkgver)
url='http://bfgminer.org/'
license=('GPL3')
source=(http://luke.dashjr.org/programs/bitcoin/files/$_pkgname/$pkgver/$_pkgname-$pkgver.txz
        remove-dangerous-rpath.patch)
sha256sums=('feec7d4ada6ceae456656b68188df05d095bbd7fc9839368f65dcd52b04f7539'
            'd26d07ca23ae25798c4db37cfda1a6a76f22d06e73efab1ddf62b3e1a7eef04c')

prepare() {
  cd "$srcdir"/$_pkgname-$pkgver

  patch -p0 < "${srcdir}"/remove-dangerous-rpath.patch
  NOSUBMODULES=1 ./autogen.sh
}

build() {
  cd "$srcdir"/$_pkgname-$pkgver

  ./configure	--prefix=/usr \
    --enable-cpumining \
    --enable-bfsb \
    --enable-metabank \
    --enable-scrypt \
    --enable-opencl \
    --with-udevrulesdir=/usr/lib/udev/rules.d
  # --enable-knc (FS#33640)
  make
}

package() {
  cd "$srcdir"/$_pkgname-$pkgver

  make DESTDIR="$pkgdir" install
}