# Maintainer: Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor: M0Rf30
# Contributor: Samsagax <samsagax@gmail.com>
# Maintainer (Parabola): André Silva <emulatorman@parabola.nu>

_pkgname=bbswitch
pkgname=bbswitch-libre
pkgver=0.7
_extramodules=extramodules-3.11-LIBRE # Don't forget to update bbswitch.install
pkgrel=17
pkgdesc="Kernel module allowing to switch dedicated graphics card on Optimus laptops (built for the linux-libre kernel package)"
arch=('i686' 'x86_64' 'mips64el')
url=("http://github.com/Bumblebee-Project/bbswitch")
license=('GPL')
depends=('linux-libre>=3.11' 'linux-libre<3.12')
makedepends=('linux-libre-headers>=3.11' 'linux-libre-headers<3.12')
replaces=$_pkgname
conflicts=$_pkgname
provides=$_pkgname=$pkgver
install=bbswitch.install
source=("https://github.com/Bumblebee-Project/bbswitch/archive/v${pkgver}.tar.gz")
md5sums=('b9df5ea40109ef9766448a0577c798e6')

build() {
  cd ${srcdir}/${_pkgname}-${pkgver}

  _kernver="$(cat /usr/lib/modules/${_extramodules}/version)"

  make KDIR=/usr/src/linux-${_kernver}
}

package() {
  cd ${srcdir}/${_pkgname}-${pkgver}
   
  install -Dm644 bbswitch.ko "${pkgdir}"/usr/lib/modules/${_extramodules}/bbswitch.ko
  gzip "${pkgdir}/usr/lib/modules/${_extramodules}/bbswitch.ko"                      
}