# $Id: PKGBUILD 116509 2014-07-29 09:43:58Z bpiotrowski $
# Maintainer (Arch): Sven-Hendrik Haase <sh@lutzhaase.com>
# Contributor (Arch): M0Rf30
# Contributor (Arch): Samsagax <samsagax@gmail.com>
# Maintainer: André Silva <emulatorman@parabola.nu>

_pkgname=bbswitch
pkgname=bbswitch-libre
pkgver=0.8
_extramodules=extramodules-3.15-libre # Don't forget to update bbswitch.install
pkgrel=14
pkgdesc="Kernel module allowing to switch dedicated graphics card on Optimus laptops (built for the linux-libre kernel package)"
arch=('i686' 'x86_64' 'mips64el')
url=("http://github.com/Bumblebee-Project/bbswitch")
license=('GPL')
depends=('linux-libre>=3.15' 'linux-libre<3.16')
makedepends=('linux-libre-headers>=3.15' 'linux-libre-headers<3.16')
replaces=($_pkgname)
conflicts=($_pkgname)
provides=($_pkgname=$pkgver)
install=bbswitch.install
source=("https://github.com/Bumblebee-Project/bbswitch/archive/v${pkgver}.tar.gz")
md5sums=('5b116b31ace3604ddf9d1fc1f4bc5807')

build() {
  cd ${srcdir}/${_pkgname}-${pkgver}

  _kernver="$(cat /usr/lib/modules/${_extramodules}/version)"

  make KDIR=/lib/modules/${_kernver}/build
}

package() {
  cd ${srcdir}/${_pkgname}-${pkgver}
   
  install -Dm644 bbswitch.ko "${pkgdir}"/usr/lib/modules/${_extramodules}/bbswitch.ko
  gzip "${pkgdir}/usr/lib/modules/${_extramodules}/bbswitch.ko"                      
}