# Maintainer (Arch): Martin Wimpress <code@flexion.org>
# Maintainer: André Silva <emulatorman@parabola.nu>

_ver=1.10
_pkgbase=atril
pkgname=(${_pkgbase})
pkgver=${_ver}.0
pkgrel=1.parabola1
pkgdesc="MATE document viewer (GTK2 version), with libarchive support for compressed comic books"
url="http://mate-desktop.org"
arch=('i686' 'x86_64' 'mips64el')
license=('GPL')
depends=('dconf' 'dbus' 'desktop-file-utils' 'gtk2' 'libsecret' 'libsm' 'libspectre'
         'mate-desktop>=1.10' 'mate-icon-theme' 'poppler-glib' 'webkitgtk2' 'zlib' 'libarchive')
makedepends=('caja>=1.10' 'djvulibre' 'gobject-introspection' 'libgxps'
             'mate-common' 'texlive-bin' 'yelp-tools')
optdepends=('caja: Document Properties extension'
            'djvulibre: DjVu support'
            'libgxps: XPS support'
            'texlive-bin: DVI support'
            'yelp: for reading MATE help documents')
groups=('mate-extra')
conflicts=("${_pkgbase}-gtk3" "${_pkgbase}-libre")
replaces=("${_pkgbase}-libre")
source=("http://pub.mate-desktop.org/releases/${_ver}/${_pkgbase}-${pkgver}.tar.xz")
sha1sums=('7abd5b9310d88cb5da05248f1c55bb9ac069ac28')
install=${_pkgbase}.install

build() {
    cd "${srcdir}/${_pkgbase}-${pkgver}"
    ./configure \
        --prefix=/usr \
        --libexecdir=/usr/lib/${_pkgbase} \
        --with-gtk=2.0 \
        --enable-gtk-doc \
        --enable-djvu \
        --enable-dvi \
        --enable-epub \
        --enable-t1lib \
        --enable-pixbuf \
        --enable-comics \
        --enable-xps \
        --enable-introspection \
        --disable-static
    make
}

package() {
    cd "${srcdir}/${_pkgbase}-${pkgver}"
    make DESTDIR="${pkgdir}" install
}