# $Id: PKGBUILD 78820 2012-10-25 06:47:28Z foutrelis $
# Maintainer (Arch): Jaroslav Lichtblau <dragonlord@aur.archlinux.org>
# Contributor (Arch): leif_thande <leif.thande@gmail.com>
# Contributor (Arch): tranquility <trankas@gmail.com>
# Contributor (Arch): Daniel J Griffiths <ghost1227@archlinux.us>
# Maintainer: Márcio Silva <coadde@parabola.nu>
# Contributor: André Silva <emulatorman@parabola.nu>

_pkgname=atool
pkgname=atool-libre
pkgver=0.39.0
pkgrel=1.3
pkgdesc="A script for managing file archives of various types, without nonfree unace and unrar support"
arch=('any')
url="http://www.nongnu.org/atool/"
license=('GPL3')
depends=('file' 'perl')
provides=("$_pkgname=$pkgver")
replaces=("$_pkgname")
conflicts=("$_pkgname")
optdepends=('bzip2: for using atool with bzip2 compressed archives'
            'cpio: for using atool with cpio archives'
            'gzip: for using atool with gzip compressed archives'
            'lha: for using atool with lha, lharc and similar archives'
            'xz: for using atool with lzma compressed archives'
            'lzop: for using atool with lzop compressed archives'
            'p7zip: for using atool with 7z archives'
            'tar: for using atool with tar archives'
            'zip: for using atool for creating zip archives'
            'unzip: for using atool for unpacking archives')
changelog=$_pkgname.changelog
source=(http://savannah.nongnu.org/download/$_pkgname/$_pkgname-$pkgver.tar.gz
        libre.patch)
sha256sums=('aaf60095884abb872e25f8e919a8a63d0dabaeca46faeba87d12812d6efc703b'
            'c9aa3c72e4c979d236dd659f16cc1eb6841f0860e6ef4d2c90f021d6e5aca578')

prepare() {
  cd ${srcdir}/${_pkgname}-${pkgver}

  # remove nonfree unace and unrar support
  patch -Np1 -i ../libre.patch
}

build() {
  cd ${srcdir}/${_pkgname}-${pkgver}

  ./configure --prefix=/usr
}

package() {
  cd ${srcdir}/${_pkgname}-${pkgver}

  make prefix=${pkgdir}/usr install
}