# Maintainer (Arch): Eli Schwartz <eschwartz@archlinux.org>
# Maintainer (Arch): Levente Polyak <anthraxx[at]archlinux[dot]org>
# Contributor (Arch): Florian Pritz <flo@xinu.at>
# Contributor (Arch): Chris Brannon <cmbrannon79@gmail.com>
# Contributor (Arch): Geoffroy Carrier <geoffroy@archlinux.org>
# Contributor (Arch): Dan McGee <dan@archlinux.org>
# Contributor (Arch): Jaroslaw Rosiek <philosoph@interia.pl>
# Contributor (Arch): Darwin Bautista <djclue917@gmail.com>
# Contributor (Arch): Daniel J Griffiths <ghost1227@archlinux.us>
# Contributor: André Silva <emulatorman@hyperbola.info>
# Contributor: Andreas Grapentin <andreas@grapentin.org>
# Contributor: Denis 'GNUtoo' Carikli <GNUtoo@cyberdimension.org>

# parabola changes and rationale:
#  - Removed fop optional dependency as fop is blacklisted


pkgname=asciidoc
pkgver=9.1.0
pkgrel=1
pkgrel+=.parabola1
pkgdesc='Text document format for short documents, articles, books and UNIX man pages'
arch=('any')
url='https://asciidoc.org/'
license=('GPL')
depends=('python' 'libxslt' 'docbook-xsl')
checkdepends=('dblatex' 'graphviz' 'lilypond' 'source-highlight')
optdepends=('graphviz: graphviz-filter'
            'lilypond: music-filter'
            'imagemagick: music-filter (used in conjunction with lilypond)'
            'source-highlight: source-highlight-filter'
            'dblatex: pdf generation'
            'w3m: text generation (alternative to lynx)'
            'lynx: text generation')
source=("https://github.com/asciidoc/asciidoc-py3/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz")
sha256sums=('8a6e3ae99785d9325fba0856e04dbe532492af3cb20d49831bfd757166d46c6b')
b2sums=('dd2376a3b9ffa1d7a8016c9eb1030a9d0d3a01cde587d3179cb425a5be5ae120ea7fc1fa971cb1bb53faa2a7e93b4a1c2e8cf854e7e960c1299398a02b8aa42e')

prepare() {
  cd ${pkgname}-py3-${pkgver}

  autoconf
}

build() {
  cd ${pkgname}-py3-${pkgver}

  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc
  make manpages
}

check() {
  cd ${pkgname}-py3-${pkgver}

  make test
}

package() {
  cd ${pkgname}-py3-${pkgver}

  make install DESTDIR="${pkgdir}"
  make docs DESTDIR="${pkgdir}"

  install -Dm644 asciidocapi.py \
    "${pkgdir}/$(python -c 'import sysconfig; print(sysconfig.get_paths()["platlib"])')"/asciidocapi.py
}