# Maintainer (Arch): schuay <jakob.gruber@gmail.com>
# Contributor (Arch): Mike Sampson <mike at sambodata dot com>
# Contributor (Arch): Adrian Stratulat <adrian.stratulat at inboxcom>
# Contributor (Arch): Anton Bazhenov <anton.bazhenov at gmail>
# Contributor (Arch): KillaB <xGenoBlast@gmail.com>
# Contributor (Arch): Callan Barrett <wizzomafizzo@gmail.com>
# Contributor (Arch): Christian Schmidt <xmucknertx@googlemail.com>
# Contributor (Arch): Sebastian Sareyko <public@nooms.de>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgname=angband
_pkgname=$pkgname-libre
pkgver=3.5.1
pkgrel=1.parabola1
pkgdesc="A roguelike dungeon exploration game based on the writings of JRR Tolkien, without nonfree artwork and sound effects"
arch=('i686' 'x86_64' 'mips64el')
url="http://rephial.org/"
license=('GPL2' 'custom')
replaces=($_pkgname)
conflicts=($_pkgname)
depends=('sdl_image' 'sdl_ttf' 'sdl_mixer' 'ncurses')
mksource=("http://rephial.org/downloads/${pkgver:0:3}/${pkgname}-v${pkgver}.tar.gz" 'libre.patch')
source=("https://repo.parabola.nu/other/${_pkgname}/${_pkgname}-v${pkgver}.tar.gz")

mksource() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  # remove nonfree parts from source code
  patch -Np1 -i ../libre.patch  
  rm -v lib/xtra/sound/*.mp3
  rm -v lib/xtra/graf/64x64.png
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  ./configure \
    --prefix=/usr \
    --bindir=/usr/bin \
    --sysconfdir=/usr/share/$pkgname \
    --with-configpath=/usr/share/$pkgname \
    --with-libpath=/usr/share/$pkgname \
    --enable-gtk \
    --enable-sdl \
    --enable-sdl-mixer

  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  make DESTDIR="${pkgdir}" install

  rm -f "${pkgdir}/usr/share/$pkgname/*/delete.me"
  install -Dm644 copying.txt "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
}

mkmd5sums=('3b9a324551cfd48b101f197a8441f135'
           '3ac39f377bea2e208308d01f4213310f')
md5sums=('b323f993d1279e560a480c669caa3710')