# Maintainer (Arch): Maxime Gauduin <alucryd@archlinux.org>
# Contributor (Arch): mortzu <me@mortzu.de>
# Contributor (Arch): fnord0 <fnord0@riseup.net>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

_basekernel=5.4.12-1

pkgbase=acpi_call
pkgname=(acpi_call acpi_call-dkms)
pkgver=1.1.0
pkgrel=235
pkgrel+=.parabola1.basekernel${_basekernel%-*}
pkgdesc='A linux kernel module that enables calls to ACPI methods through /proc/acpi/call'
pkgdesc+=' (built for the linux-libre kernel package)'
url='https://github.com/mkottman/acpi_call'
arch=('x86_64')
arch+=('i686')
license=('GPL')
makedepends=(linux-libre-headers=${_basekernel%-*} git libelf)
source=("acpi_call-${pkgver}.tar.gz::https://github.com/mkottman/acpi_call/archive/v${pkgver}.tar.gz"
        dkms.conf)
sha256sums=('d0d14b42944282724fca76f57d598eed794ef97448f387d1c489d85ad813f2f0'
            '32e6ea6523b13132c6c7838bba7fbf3d040ba2d35a892c2c356245612720df8a')

prepare() {
  cd $pkgbase-$pkgver

  # Fix build with Linux-libre >= 3.17-gnu
  sed -i 's|acpi/acpi.h|linux/acpi.h|' acpi_call.c

  # Fix build with Linux-libre >= 4.12-gnu
  sed -i 's|asm/uaccess.h|linux/uaccess.h|' acpi_call.c
}

build() {
  cd $pkgbase-$pkgver
  make KVERSION="$(</usr/src/linux-libre/version)"
}

package_acpi_call() {
  depends=(linux-libre=${_basekernel%-*})

  cd $pkgbase-$pkgver
  _extradir="/usr/lib/modules/$(</usr/src/linux-libre/version)/extramodules"
  install -Dt "$pkgdir$_extradir" -m644 *.ko
  find "$pkgdir" -name '*.ko' -exec xz {} +

  echo acpi_call | install -Dm644 /dev/stdin "$pkgdir/usr/lib/modules-load.d/$pkgname.conf"

  mkdir -p "$pkgdir/usr/share/acpi_call"
  cp -t "$pkgdir/usr/share/acpi_call" -dr --no-preserve=ownership examples support
}

package_acpi_call-dkms() {
  depends=(dkms)
  provides=("acpi_call=$pkgver-${pkgrel%%.*}")
  conflicts=(acpi_call)

  cd $pkgbase-$pkgver
  install -Dt "$pkgdir/usr/src/$pkgbase-$pkgver" -m644 Makefile acpi_call.c ../dkms.conf

  echo acpi_call | install -Dm644 /dev/stdin "$pkgdir/usr/lib/modules-load.d/acpi_call.conf"

  mkdir -p "$pkgdir/usr/share/acpi_call"
  cp -t "$pkgdir/usr/share/acpi_call" -dr --no-preserve=ownership examples support
}

# vim:set ts=2 sw=2 et: