# $Id: PKGBUILD 116819 2014-08-04 07:10:28Z tpowa $
# Maintainer (Arch): Maxime Gauduin <alucryd@gmail.com>
# Contributor (Arch): mortzu <me@mortzu.de>
# Contributor (Arch): fnord0 <fnord0@riseup.net>
# Maintainer: André Silva <emulatorman@parabola.nu>
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>

# Kernel info
_basekernel=3.15
_kernelname=-grsec

# Source info
_pkgname=acpi_call
pkgver=1.1.0
pkgdesc="A linux kernel module that enables calls to ACPI methods through /proc/acpi/call (built for the linux-libre${_kernelname} kernel package)"
url="http://github.com/mkottman/${_pkgname}"
license=('GPL')
source=("${url}/archive/v${pkgver}.tar.gz")
sha256sums=('d0d14b42944282724fca76f57d598eed794ef97448f387d1c489d85ad813f2f0')

# Package info
pkgrel=12.${_basekernel/./}
arch=('i686' 'x86_64')
install='kmod.install'
_replaces=("${_pkgname}" "${_pkgname}-libre")

# Generic (you shouldn't have to modify any of these variables)
pkgname=${_pkgname}-parabola${_kernelname}
_toohigh=$(IFS=. read a b <<<$_basekernel; echo $a.$((b+1)))
_extramodules=extramodules-${_basekernel}${_kernelname}
depends=("linux-libre${_kernelname}>=${_basekernel}" "linux-libre${_kernelname}<${_toohigh}")
makedepends=("linux-libre${_kernelname}-headers>=${_basekernel}" "linux-libre${_kernelname}-headers<${_toohigh}")
replaces=( "${_replaces[@]/%/${_kernelname}}")
conflicts=("${_replaces[@]/%/${_kernelname}}")
provides=( "${_replaces[@]/%/${_kernelname}=${_pkgver}}")
if [[ -n "${_kernelname}" ]]; then
  provides+=("${_pkgname}-parabola=${pkgver}") # pkgname without _kernelname
fi

build() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  _kernver="$(cat /usr/lib/modules/${_extramodules}/version)"

  make KVERSION="${_kernver}"
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"

  # Set the correct extramodules directory for install
  cp -f "${startdir}/${install}" "${startdir}/${install}.pkg"
  true && install=${install}.pkg
  sed -r "s/(_extramodules=).*/\1${_extramodules}/" -i "${startdir}/${install}"

  # Actually install
  install -dm 755 "${pkgdir}"/usr/lib/{modules/${_extramodules},modules-load.d}
  install -m 644 ${_pkgname}.ko "${pkgdir}"/usr/lib/modules/${_extramodules}
  gzip "${pkgdir}"/usr/lib/modules/${_extramodules}/${_pkgname}.ko
  echo ${_pkgname} > "${pkgdir}"/usr/lib/modules-load.d/${pkgname}.conf

  install -dm 755 "${pkgdir}"/usr/share/${pkgname}
  cp -dr --no-preserve='ownership' {examples,support} "${pkgdir}"/usr/share/${pkgname}/
}