# Maintainer (Arch): Maxime Gauduin <alucryd@gmail.com>
# Contributor (Arch): mortzu <me@mortzu.de>
# Contributor (Arch): fnord0 <fnord0@riseup.net>
# Contributor (Hyperbola): André Silva <emulatorman@hyperbola.info>
# Contributor (Hyperbola): Márcio Silva <coadde@hyperbola.info>
# Maintainer: Omar Vega Ramos <ovruni@gnu.org.pe>

_basekernel=4.14
_archrel=69
_parabolarel=1

pkgname=acpi_call-lts
pkgver=1.1.0
pkgrel=${_archrel}.parabola${_parabolarel}.basekernel${_basekernel}
_extramodules=extramodules-${_basekernel}-lts
pkgdesc="A linux kernel module that enables calls to ACPI methods through /proc/acpi/call (built for the linux-libre-lts kernel package)"
arch=('i686' 'x86_64' 'armv7h')
url="http://github.com/mkottman/acpi_call"
license=('GPL')

# Generic (you shouldn't have to modify any of these variables)
_toohigh=$(IFS=. read a b <<<$_basekernel; echo $a.$((b+1)))
depends=("linux-libre-lts>=${_basekernel}" "linux-libre-lts<${_toohigh}")
makedepends=("linux-libre-lts-headers>=${_basekernel}" "linux-libre-lts-headers<${_toohigh}" "linux-libre-lts>=${_basekernel}" "linux-libre-lts<${_toohigh}")
makedepends+=('libelf')

replaces=("${pkgname%-*}-libre-lts" "${pkgname%-*}-parabola-lts" "${pkgname}-parabola")
conflicts=("${pkgname%-*}-libre-lts" "${pkgname%-*}-parabola-lts" "${pkgname}-parabola")
provides=("acpi_call")

source=("${pkgname%-*}-${pkgver}.tar.gz::${url}/archive/v${pkgver}.tar.gz")
sha256sums=('d0d14b42944282724fca76f57d598eed794ef97448f387d1c489d85ad813f2f0')

prepare() {
  cd "${pkgname%-*}-${pkgver}"

  # Fix build with Linux-libre >= 3.17-gnu
  sed -i 's|acpi/acpi.h|linux/acpi.h|' acpi_call.c
  # Fix build with Linux-libre >= 4.12
  sed -i 's|asm/uaccess.h|linux/uaccess.h|' acpi_call.c
}

build() {
  cd "${pkgname%-*}-${pkgver}"

  _kernver="$(cat /usr/lib/modules/${_extramodules}/version)"

  make KVERSION="${_kernver}"
}

package() {
  cd "${pkgname%-*}-$pkgver"

  # Actually install  
  install -dm 755 "${pkgdir}"/usr/lib/{modules/${_extramodules},modules-load.d}
  install -m 644 ${pkgname%-*}.ko "${pkgdir}"/usr/lib/modules/${_extramodules}
  gzip "${pkgdir}"/usr/lib/modules/${_extramodules}/${pkgname%-*}.ko
  echo ${pkgname%-*} > "${pkgdir}"/usr/lib/modules-load.d/${pkgname}.conf

  install -dm 755 "${pkgdir}"/usr/share/${pkgname}
  cp -dr --no-preserve='ownership' {examples,support} "${pkgdir}"/usr/share/${pkgname}/
}

# vim:set ts=2 sw=2 et: