# $Id: PKGBUILD 101370 2013-11-23 19:00:48Z arodseth $
# Maintainer (Arch): Alexander Rødseth <rodseth@gmail.com>
# Contributor (Arch): Lukas Fleischer <archlinux at cryptocrack dot de>
# Contributor (Arch): jlvsimoes <jlvsimoes@oninet.pt>
# Contributor (Arch): kevin <kevin@archlinux.org>
# Contributor: André Silva <emulatorman@parabola.nu>
# Contributor: Márcio Silva <coadde@parabola.nu>

pkgname=abuse
_pkgname=$pkgname-libre
pkgver=0.8
pkgrel=4
pkgdesc='Side-scroller action game that pits you against ruthless alien killers, without nonfree claudio support'
arch=('x86_64' 'i686' 'mips64el')
url="http://$pkgname.zoy.org/"
license=('GPL' 'custom')
replaces=($_pkgname)
conflicts=($_pkgname)
depends=('gcc-libs' 'libgl' 'sdl_mixer' 'glu' 'desktop-file-utils')
makedepends=('gendesk' 'mesa-libgl' 'glu')
install="$pkgname.install"
mksource=("http://$pkgname.zoy.org/raw-attachment/wiki/download/$pkgname-$pkgver.tar.gz"
          'non-claudio.patch')
source=("https://repo.parabolagnulinux.org/other/$_pkgname/$_pkgname-$pkgver.tar.gz"
        "$pkgname.sh"
        "default.${pkgname}rc"
        'default.gamma.lsp')
mksha256sums=('0104db5fd2695c9518583783f7aaa7e5c0355e27c5a803840a05aef97f9d3488'
              '017cb58acf5ba8cdb889f97a758318cb66ab4947b860a77ab16b932c3f21b98f')
sha256sums=('ff7018b3ddcc6d2e702bc14eb2884622677ac5141c36e1fc0cdd127df3017f7d'
            'a5ddac71ca9b8c4bb42bdf91393a5fbe3d839ab9a9e9a6362a75dafc2aab122e'
            '6ea2fa9e65c10bbcab4432f40d0c7284cb3970835c40c5c00ced14b39ce1b00f'
            '13df83fea60918d29d5141cdfbd8d56147c053e88d3701209ae676f46447c2f6')

mksource() {
  cd "$pkgname-$pkgver"

  # Remove the nonfree claudio addon
  rm -rvf ./data/addon/claudio
  patch -Np1 -i "$srcdir/non-claudio.patch"
}

prepare() {
  cd "$pkgname-$pkgver"

  gendesk -n -f --pkgname "$pkgname" --pkgdesc "$pkgdesc"
}

build() {
  cd "$pkgname-$pkgver"

  ./configure --prefix=/usr --with-assetdir="/usr/share/$pkgname/orig" --with-x
  make
}

package() {
  cd "$pkgname-$pkgver"

  make DESTDIR="$pkgdir" install

  # Desktop shortcut and icon
  install -Dm644 "$pkgname.desktop" \
    "$pkgdir/usr/share/applications/$pkgname.desktop"
  install -Dm644 "doc/$pkgname.png" "$pkgdir/usr/share/pixmaps/$pkgname.png"

  # Sane defaults
  mv "$pkgdir/usr/bin/$pkgname" "$pkgdir/usr/bin/$pkgname.elf"
  install -Dm755 "$srcdir/$pkgname.sh" "$pkgdir/usr/bin/$pkgname"
  install -Dm644 "$srcdir/default.${pkgname}rc" \
    "$pkgdir/usr/share/$pkgname/default.${pkgname}rc"
  install -Dm644 "$srcdir/default.gamma.lsp" \
    "$pkgdir/usr/share/$pkgname/default.gamma.lsp"

  # License (for the original source code)
  install -d "$pkgdir/usr/share/licenses/$pkgname"
  sed -n '1,/^$/p' src/view.cpp > "$pkgdir/usr/share/licenses/$pkgname/original"
}

# vim:set ts=2 sw=2 et: