# Maintainer: Joshua Haase <hahj87@gmail.com
# Contributor: Luke Shumaker <lukeshu@sbcglobal.net>
# Contributor: fauno <fauno@kiwwwi.com.ar>

pkgbase=libretools
pkgname=(libretools libretools-mips64el)
pkgdesc="Programs for Parabola development"
url="https://projects.parabolagnulinux.org/packages/libretools.git/"
license=('GPL3' 'GPL2')

pkgver=20130522
_libretools_commit=379ff751c59d528bd4f1a8e7a24fc039e8e408ba
_devtools_commit=89d15e7697da2169493142f78a90b57a784d8f22

_packages_url=https://projects.parabolagnulinux.org/packages
source=($_packages_url/libretools.git/snapshot/libretools-$_libretools_commit.tar.bz2
	$_packages_url/devtools-par.git/snapshot/devtools-par-$_devtools_commit.tar.bz2)

pkgrel=1
arch=('any')
makedepends=(emacs) # emacs --batch is used during the build to process text

build() {
  cd "$srcdir"
  ln -sf devtools-par-$_devtools_commit devtools-par
  cd "$srcdir/$pkgbase-$_libretools_commit"
  make build-libretools build-libretools-mips64el build-doc
}

package_libretools() {
  backup=(etc/libretools.conf etc/libretools.d/chroot.conf etc/libretools.d/librefetch.conf)
  install=libretools.install
  groups=(base-devel)
  replaces=(chroottools)

  depends=(
    arch-install-scripts # `archroot` uses `pacstrap`
    git # `createworkdir`
    openssh # `librerelease`
    rsync # `librerelease` and `makechrootpkg.sh`
    subversion # `diff-unfree`
    tokyocabinet # `treepkg`
    wget # `aur` and `lib/blacklist.sh`
  )
  optdepends=('namcap: to check package files')

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-libretools install-doc DESTDIR="$pkgdir"
}

package_libretools-mips64el() {
  pkgdesc="Scripts for Parabola development (for mips64el architecture)"
  backup=('etc/libretools.d/mips64el.conf')
  depends=("$pkgbase=$pkgver")

  cd "$srcdir/$pkgbase-$_libretools_commit"
  make install-libretools-mips64el DESTDIR="$pkgdir"
}

md5sums=('1fac1e8166cc5b686ed3fe6d99588c21'
         '21d77c519a7496185c40399d1cfa26bf')